Puppet Class: collectd::plugin::exec

Defined in:
manifests/plugin/exec.pp

Overview

See collectd.org/documentation/manpages/collectd.conf.5.shtml#plugin_exec

Parameters:

  • commands (Hash) (defaults to: {})
  • commands_defaults (Hash) (defaults to: {})
  • interval (Any) (defaults to: undef)
  • ensure (Any) (defaults to: 'present')
  • globals (Boolean) (defaults to: false) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
# File 'manifests/plugin/exec.pp', line 2

class collectd::plugin::exec (
  Hash $commands          = {},
  Hash $commands_defaults = {},
  $interval               = undef,
  $ensure                 = 'present',
  Boolean $globals        = false,
) {
  include collectd

  collectd::plugin { 'exec':
    ensure   => $ensure,
    globals  => $globals,
    interval => $interval,
  }

  # should be loaded after global plugin configuration
  $exec_conf = "${collectd::plugin_conf_dir}/exec-config.conf"

  concat { $exec_conf:
    ensure         => $ensure,
    mode           => $collectd::config_mode,
    owner          => $collectd::config_owner,
    group          => $collectd::config_group,
    notify         => Service[$collectd::service_name],
    ensure_newline => true,
  }

  concat::fragment { 'collectd_plugin_exec_conf_header':
    order   => '00',
    content => '<Plugin exec>',
    target  => $exec_conf,
  }

  concat::fragment { 'collectd_plugin_exec_conf_footer':
    order   => '99',
    content => '</Plugin>',
    target  => $exec_conf,
  }

  $commands.each |String $resource, Hash $attributes| {
    collectd::plugin::exec::cmd { $resource:
      * => $commands_defaults + $attributes,
    }
  }
}