Puppet Class: collectd::plugin::processes

Defined in:
manifests/plugin/processes.pp

Overview

See collectd.org/documentation/manpages/collectd.conf.5.shtml#plugin_processes

Parameters:

  • ensure (Enum['present', 'absent']) (defaults to: 'present')
  • order (Integer) (defaults to: 10)
  • interval (Optional[Numeric]) (defaults to: undef)
  • processes (Optional[Array]) (defaults to: undef)
  • process_matches (Optional[Array]) (defaults to: undef)
  • collect_context_switch (Optional[Boolean]) (defaults to: undef)
  • collect_file_descriptor (Optional[Boolean]) (defaults to: undef)
  • collect_memory_maps (Optional[Boolean]) (defaults to: undef) 


2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
 
# File 'manifests/plugin/processes.pp', line 2

class collectd::plugin::processes (
  Enum['present', 'absent'] $ensure          = 'present',
  Integer $order                             = 10,
  Optional[Numeric] $interval                = undef,
  Optional[Array] $processes                 = undef,
  Optional[Array] $process_matches           = undef,
  Optional[Boolean] $collect_context_switch  = undef,
  Optional[Boolean] $collect_file_descriptor = undef,
  Optional[Boolean] $collect_memory_maps     = undef,
) {
  include collectd

  $processes_defaults       = { 'ensure' => $ensure }
  $process_matches_defaults = { 'ensure' => $ensure }

  collectd::plugin { 'processes':
    ensure   => $ensure,
    order    => $order,
    interval => $interval,
  }

  concat { "${collectd::plugin_conf_dir}/processes_config.conf":
    ensure         => $ensure,
    mode           => $collectd::config_mode,
    owner          => $collectd::config_owner,
    group          => $collectd::config_group,
    notify         => Service[$collectd::service_name],
    ensure_newline => true,
  }
  concat::fragment { 'collectd_plugin_processes_conf_header':
    order   => '00',
    content => epp('collectd/plugin/processes-header.conf.epp'),
    target  => "${collectd::plugin_conf_dir}/processes_config.conf",
  }

  concat::fragment { 'collectd_plugin_processes_conf_footer':
    order   => '99',
    content => '</Plugin>',
    target  => "${collectd::plugin_conf_dir}/processes_config.conf",
  }

  if $processes {
    $process_resources = collectd_convert_processes($processes)
    $process_resources.each |String $resource, Hash $attributes| {
      collectd::plugin::processes::process { $resource:
        * => $processes_defaults + $attributes,
      }
    }
  }

  if $process_matches {
    $process_matches_resources = collectd_convert_processes($process_matches)
    $process_matches_resources.each |String $resource, Hash $attributes| {
      collectd::plugin::processes::processmatch { $resource:
        * => $process_matches_defaults + $attributes,
      }
    }
  }
}