Puppet Class: firewalld
- Defined in:
- manifests/init.pp
Summary
Manage the firewalld serviceOverview
See the README.md for usage instructions for the firewalld_zone and firewalld_rich_rule types
Examples
Standard:
include firewalld
Command line only, no GUI components:
class{'firewalld':
}
With GUI components
class{'firewalld':
install_gui => true,
}
Documentation
Authors
Craig Dunn <craig@craigdunn.org>
Copyright
Copyright 2015 Craig Dunn
128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 |
# File 'manifests/init.pp', line 128
class firewalld (
Enum['present','absent','latest','installed'] $package_ensure = 'installed',
String $package = 'firewalld',
Stdlib::Ensure::Service $service_ensure = 'running',
String $config_package = 'firewall-config',
Boolean $install_gui = false,
Boolean $service_enable = true,
Hash $zones = {},
Hash $policies = {},
Hash $ports = {},
Hash $services = {},
Hash $rich_rules = {},
Hash $custom_services = {},
Hash $ipsets = {},
Hash $direct_rules = {},
Hash $direct_chains = {},
Hash $direct_passthroughs = {},
Boolean $purge_direct_rules = false,
Boolean $purge_direct_chains = false,
Boolean $purge_direct_passthroughs = false,
Boolean $purge_unknown_ipsets = false,
Optional[String] $default_zone = undef,
Optional[Enum['off','all','unicast','broadcast','multicast']] $log_denied = undef,
Optional[Enum['yes', 'no']] $cleanup_on_exit = undef,
Optional[Enum['yes', 'no']] $zone_drifting = undef,
Optional[Integer] $minimal_mark = undef,
Optional[Enum['yes', 'no']] $lockdown = undef,
Optional[Enum['yes', 'no']] $individual_calls = undef,
Optional[Enum['yes', 'no']] $ipv6_rpfilter = undef,
Optional[Enum['iptables', 'nftables']] $firewall_backend = undef,
Optional[String] $default_service_zone = undef,
Optional[String] $default_port_zone = undef,
Optional[String] $default_port_protocol = undef,
) {
include firewalld::reload
include firewalld::reload::complete
package { $package:
ensure => $package_ensure,
notify => Service['firewalld'],
}
if $install_gui {
package { $config_package:
ensure => installed,
}
}
Exec {
path => '/usr/bin:/bin',
}
service { 'firewalld':
ensure => $service_ensure,
enable => $service_enable,
}
# create ports
Firewalld_port {
zone => $default_port_zone,
protocol => $default_port_protocol,
}
$ports.each |String $key, Hash $attrs| {
firewalld_port { $key:
* => $attrs,
}
}
#...zones
$zones.each | String $key, Hash $attrs| {
firewalld_zone { $key:
* => $attrs,
}
}
#...policies
$policies.each | String $key, Hash $attrs| {
firewalld_policy { $key:
* => $attrs,
}
}
#...services
Firewalld_service {
zone => $default_service_zone,
}
$services.each | String $key, Hash $attrs| {
firewalld_service { $key:
* => $attrs,
}
}
#...rich rules
$rich_rules.each | String $key, Hash $attrs| {
firewalld_rich_rule { $key:
* => $attrs,
}
}
#...custom services
$custom_services.each | String $key, Hash $attrs| {
firewalld_custom_service { $key:
* => $attrs,
}
}
#...ipsets
$ipsets.each | String $key, Hash $attrs| {
firewalld_ipset { $key:
* => $attrs,
}
}
# Direct rules, chains and passthroughs
$direct_chains.each | String $key, Hash $attrs| {
firewalld_direct_chain { $key:
* => $attrs,
}
}
$direct_rules.each | String $key, Hash $attrs| {
firewalld_direct_rule { $key:
* => $attrs,
}
}
$direct_passthroughs.each | String $key, Hash $attrs| {
firewalld_direct_passthrough { $key:
* => $attrs,
}
}
Firewalld_direct_purge {
notify => Class['firewalld::reload'],
}
if $purge_direct_chains {
firewalld_direct_purge { 'chain': }
}
if $purge_direct_rules {
firewalld_direct_purge { 'rule': }
}
if $purge_direct_passthroughs {
firewalld_direct_purge { 'passthrough': }
}
if $default_zone {
exec { 'firewalld::set_default_zone':
command => 'true',
unless => 'true',
require => [Exec['firewalld::set_default_zone_active'], Exec['firewalld::set_default_zone_offline'], Service['firewalld']],
}
exec { 'firewalld::set_default_zone_active':
command => ['firewall-cmd', '--set-default-zone', $default_zone],
unless => "[ $(firewall-cmd --get-default-zone) = ${default_zone} ]",
onlyif => 'firewall-cmd --state',
require => Service['firewalld'],
}
exec { 'firewalld::set_default_zone_offline':
command => ['firewall-offline-cmd', '--set-default-zone', $default_zone],
unless => ["[ $(firewall-offline-cmd --get-default-zone) = ${default_zone} ]", 'firewall-cmd --state',],
}
Firewalld_zone <||> -> Exec['firewalld::set_default_zone']
Firewalld_zone <||> -> Exec['firewalld::set_default_zone_active']
Firewalld_zone <||> -> Exec['firewalld::set_default_zone_offline']
}
if $log_denied {
exec { 'firewalld::set_log_denied':
command => 'true',
unless => 'true',
require => [Exec['firewalld::set_log_denied_active'], Exec['firewalld::set_log_denied_offline'], Service['firewalld']],
}
exec { 'firewalld::set_log_denied_active':
command => ['firewall-cmd', '--set-log-denied', $log_denied],
unless => "[ $(firewall-cmd --get-log-denied) = ${log_denied} ]",
onlyif => 'firewall-cmd --state',
require => Service['firewalld'],
}
exec { 'firewalld::set_log_denied_offline':
command => ['firewall-offline-cmd', '--set-log-denied', $log_denied],
unless => ["[ $(firewall-offline-cmd --get-log-denied) = ${log_denied} ]", 'firewall-cmd --state'],
}
}
Augeas {
lens => 'Shellvars.lns',
incl => '/etc/firewalld/firewalld.conf',
notify => [
Class['firewalld::reload'],
Service['firewalld'],
],
}
if $cleanup_on_exit {
augeas {
'firewalld::cleanup_on_exit':
changes => [
"set CleanupOnExit \"${cleanup_on_exit}\"",
];
}
}
if $zone_drifting {
augeas {
'firewalld::zone_drifting':
changes => [
"set AllowZoneDrifting \"${zone_drifting}\"",
];
}
}
if $minimal_mark {
augeas {
'firewalld::minimal_mark':
changes => [
"set MinimalMark \"${minimal_mark}\"",
];
}
}
if $lockdown {
augeas {
'firewalld::lockdown':
changes => [
"set Lockdown \"${lockdown}\"",
];
}
}
if $individual_calls {
augeas {
'firewalld::individual_calls':
changes => [
"set IndividualCalls \"${individual_calls}\"",
];
}
}
if $ipv6_rpfilter {
augeas {
'firewalld::ipv6_rpfilter':
changes => [
"set IPv6_rpfilter \"${ipv6_rpfilter}\"",
];
}
}
if $facts['firewalld_version'] and
(versioncmp($facts['firewalld_version'], '0.6.0') >= 0) and
$firewall_backend {
augeas {
'firewalld::firewall_backend':
changes => [
"set FirewallBackend \"${firewall_backend}\"",
];
}
}
# TODO: Replace these with a native firewalld_reload type and automatically
# hook the types together properly.
Firewalld_direct_chain <||> ~> Class['firewalld::reload']
Firewalld_direct_passthrough <||> ~> Class['firewalld::reload']
Firewalld_direct_purge <||> ~> Class['firewalld::reload']
Firewalld_direct_rule <||> ~> Class['firewalld::reload']
Firewalld_ipset <||> ~> Class['firewalld::reload']
Firewalld_port <||> ~> Class['firewalld::reload']
Firewalld_rich_rule <||> ~> Class['firewalld::reload']
Firewalld_service <||> ~> Class['firewalld::reload']
if $purge_unknown_ipsets {
Firewalld_ipset <||>
~> resources { 'firewalld_ipset':
purge => true,
}
}
}
|