Puppet Class: k8s::install::cni_plugins

Defined in:
manifests/install/cni_plugins.pp

Summary

manages the installation of the cni plugins

Overview

Class: k8s::install::cni_plugins

Parameters:

  • ensure (K8s::Ensure) (defaults to: $k8s::ensure) —

    set ensure for installation or deinstallation

  • version (String[1]) (defaults to: 'v1.2.0') —

    sets the version to use

  • arch (String[1]) (defaults to: 'amd64') —

    sets the arch to use for binary download

  • method (String[1]) (defaults to: $k8s::native_packaging) —

    installation method



10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
 
# File 'manifests/install/cni_plugins.pp', line 10

class k8s::install::cni_plugins (
  K8s::Ensure $ensure = $k8s::ensure,
  String[1] $version  = 'v1.2.0',
  String[1] $arch     = 'amd64',
  String[1] $method   = $k8s::native_packaging,
) {
  file {
    default:
      ensure => directory;

    '/etc/cni': ;
    '/etc/cni/net.d': ;
    '/opt/cni': ;
  }

  case $method {
    'tarball', 'loose': {
      file { '/opt/cni/bin':
        ensure => directory,
      }

      archive { 'cni-plugins':
        ensure       => $ensure,
        path         => "/tmp/cni-plugins-linux--${arch}-${version}.tgz",
        source       => "https://github.com/containernetworking/plugins/releases/download/${version}/cni-plugins-linux-${arch}-${version}.tgz",
        extract      => true,
        extract_path => '/opt/cni/bin',
        creates      => '/opt/cni/bin/bridge',
        cleanup      => true,
        require      => File['/opt/cni/bin'],
      }
    }
    'package':{
      ensure_packages(['containernetworking-plugins',])

      file { '/opt/cni/bin':
        ensure  => link,
        target  => '/usr/lib/cni',
        require => Package['containernetworking-plugins'],
      }

      if $k8s::manage_repo {
        Class['k8s::repo'] -> Package['containernetworking-plugins']
      }
    }
    default: {
      fail("install method ${method} not supported")
    }
  }
}