Puppet Class: kafka::consumer::service

Defined in:
manifests/consumer/service.pp

Overview

Class: kafka::consumer::service

This private class is meant to be called from ‘kafka::consumer`. It manages the kafka-consumer service

Parameters:

  • user (String) (defaults to: $kafka::consumer::user)
  • group (String) (defaults to: $kafka::consumer::group)
  • config_dir (Stdlib::Absolutepath) (defaults to: $kafka::consumer::config_dir)
  • log_dir (Stdlib::Absolutepath) (defaults to: $kafka::consumer::log_dir)
  • bin_dir (Stdlib::Absolutepath) (defaults to: $kafka::consumer::bin_dir)
  • service_name (String) (defaults to: $kafka::consumer::service_name)
  • service_install (Boolean) (defaults to: $kafka::consumer::service_install)
  • service_ensure (Enum['running', 'stopped']) (defaults to: $kafka::consumer::service_ensure)
  • service_requires (Array[String]) (defaults to: $kafka::consumer::service_requires)
  • limit_nofile (Optional[String]) (defaults to: $kafka::consumer::limit_nofile)
  • limit_core (Optional[String]) (defaults to: $kafka::consumer::limit_core)
  • env (Hash) (defaults to: $kafka::consumer::env)
  • jmx_opts (String) (defaults to: $kafka::consumer::jmx_opts)
  • log4j_opts (String) (defaults to: $kafka::consumer::log4j_opts)
  • service_config (Hash) (defaults to: $kafka::consumer::service_config) 


10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
 
# File 'manifests/consumer/service.pp', line 10

class kafka::consumer::service(
  String $user                               = $kafka::consumer::user,
  String $group                              = $kafka::consumer::group,
  Stdlib::Absolutepath $config_dir           = $kafka::consumer::config_dir,
  Stdlib::Absolutepath $log_dir              = $kafka::consumer::log_dir,
  Stdlib::Absolutepath $bin_dir              = $kafka::consumer::bin_dir,
  String $service_name                       = $kafka::consumer::service_name,
  Boolean $service_install                   = $kafka::consumer::service_install,
  Enum['running', 'stopped'] $service_ensure = $kafka::consumer::service_ensure,
  Array[String] $service_requires            = $kafka::consumer::service_requires,
  Optional[String] $limit_nofile             = $kafka::consumer::limit_nofile,
  Optional[String] $limit_core               = $kafka::consumer::limit_core,
  Hash $env                                  = $kafka::consumer::env,
  String $jmx_opts                           = $kafka::consumer::jmx_opts,
  String $log4j_opts                         = $kafka::consumer::log4j_opts,
  Hash $service_config                       = $kafka::consumer::service_config,
) {

  if $caller_module_name != $module_name {
    fail("Use of private class ${name} by ${caller_module_name}")
  }

  if $service_install {

    if $service_config['topic'] == '' {
      fail('[Consumer] You need to specify a value for topic')
    }
    if $service_config['zookeeper'] == '' {
      fail('[Consumer] You need to specify a value for zookeeper')
    }

    $env_defaults = {
      'KAFKA_JMX_OPTS'   => $jmx_opts,
      'KAFKA_LOG4J_OPTS' => $log4j_opts,
    }
    $environment = deep_merge($env_defaults, $env)

    if $::service_provider == 'systemd' {
      include ::systemd

      file { "/etc/systemd/system/${service_name}.service":
        ensure  => file,
        mode    => '0644',
        content => template('kafka/unit.erb'),
      }

      file { "/etc/init.d/${service_name}":
        ensure => absent,
      }

      File["/etc/systemd/system/${service_name}.service"]
      ~> Exec['systemctl-daemon-reload']
      -> Service[$service_name]

    } else {
      file { "/etc/init.d/${service_name}":
        ensure  => file,
        mode    => '0755',
        content => template('kafka/init.erb'),
        before  => Service[$service_name],
      }
    }

    service { $service_name:
      ensure     => $service_ensure,
      enable     => true,
      hasstatus  => true,
      hasrestart => true,
    }
  }
}