Puppet Class: nodejs::install

Defined in:
manifests/install.pp

Overview

PRIVATE CLASS: do not call directly



2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
 
# File 'manifests/install.pp', line 2

class nodejs::install {

  $npmrc_auth = $::nodejs::npmrc_auth
  $npmrc_config = $::nodejs::npmrc_config

  if $caller_module_name != $module_name {
    fail("Use of private class ${name} by ${caller_module_name}")
  }

  # npm is a Gentoo USE flag
  if $facts['os']['name'] == 'Gentoo' {
    package_use { $nodejs::nodejs_package_name:
      ensure => present,
      target => 'nodejs-flags',
      use    => $nodejs::use_flags,
      before => Package[$nodejs::nodejs_package_name],
    }
  }

  Package { provider => $nodejs::package_provider }

  # nodejs
  package { $nodejs::nodejs_package_name:
    ensure => $nodejs::nodejs_package_ensure,
    tag    => 'nodesource_repo',
  }

  # nodejs-development
  if $nodejs::nodejs_dev_package_name {
    package { $nodejs::nodejs_dev_package_name:
      ensure => $nodejs::nodejs_dev_package_ensure,
      tag    => 'nodesource_repo',
    }
  }

  # nodejs-debug
  if $nodejs::nodejs_debug_package_name {
    package { $nodejs::nodejs_debug_package_name:
      ensure => $nodejs::nodejs_debug_package_ensure,
      tag    => 'nodesource_repo',
    }
  }

  # npm
  if $nodejs::npm_package_name and $nodejs::npm_package_name != false {
    package { $nodejs::npm_package_name:
      ensure => $nodejs::npm_package_ensure,
      tag    => 'nodesource_repo',
    }
  }

  if $facts['os']['name'] != 'Windows' {
    file { 'root_npmrc':
      ensure  => 'file',
      path    => "${facts['root_home']}/.npmrc",
      content => template('nodejs/npmrc.erb'),
      owner   => 'root',
      group   => '0',
      mode    => '0600',
    }
  }
}