Defined Type: openvpn::ca

Defined in:
manifests/ca.pp

Summary

This define creates the openvpn ca and ssl certificates

Overview

Examples:

openvpn::ca {
  'my_user':
    server      => 'contractors',
    remote_host => 'vpn.mycompany.com'
 }

Parameters:

  • country (Optional[String]) (defaults to: undef) —

    Country to be used for the SSL certificate

  • province (Optional[String]) (defaults to: undef) —

    Province to be used for the SSL certificate

  • city (Optional[String]) (defaults to: undef) —

    City to be used for the SSL certificate

  • organization (Optional[String]) (defaults to: undef) —

    Organization to be used for the SSL certificate

  • email (Optional[String]) (defaults to: undef) —

    Email address to be used for the SSL certificate

  • common_name (String) (defaults to: 'server') —

    Common name to be used for the SSL certificate

  • group (Optional[String]) (defaults to: undef) —

    User to drop privileges to after startup

  • ssl_key_size (Integer) (defaults to: 2048) —

    Length of SSL keys (in bits) generated by this module.

  • key_expire (Integer) (defaults to: 3650) —

    The number of days to certify the server certificate for

  • ca_expire (Integer) (defaults to: 3650) —

    The number of days to certify the CA certificate for

  • key_name (Optional[String]) (defaults to: undef) —

    Value for name_default variable in openssl.cnf and KEY_NAME in vars

  • key_ou (Optional[String]) (defaults to: undef) —

    Value for organizationalUnitName_default variable in openssl.cnf and KEY_OU in vars

  • key_cn (Optional[String]) (defaults to: undef) —

    Value for commonName_default variable in openssl.cnf and KEY_CN in vars

  • tls_auth (Boolean) (defaults to: false) —

    Determins if a tls key is generated

  • tls_static_key (Boolean) (defaults to: false) —

    Determins if a tls key is generated

  • crl_days (Integer) (defaults to: 30) 


25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
 
# File 'manifests/ca.pp', line 25

define openvpn::ca (
  Optional[String] $country      = undef,
  Optional[String] $province     = undef,
  Optional[String] $city         = undef,
  Optional[String] $organization = undef,
  Optional[String] $email        = undef,
  String $common_name            = 'server',
  Optional[String] $group        = undef,
  Integer $ssl_key_size          = 2048,
  Integer $ca_expire             = 3650,
  Integer $key_expire            = 3650,
  Integer $crl_days              = 30,
  Optional[String] $key_cn       = undef,
  Optional[String] $key_name     = undef,
  Optional[String] $key_ou       = undef,
  Boolean $tls_auth              = false,
  Boolean $tls_static_key        = false,
) {
  if $tls_auth {
    warning('Parameter $tls_auth is deprecated. Use $tls_static_key instead.')
  }

  include openvpn
  $group_to_set = $group ? {
    undef   => $openvpn::group,
    default => $group
  }

  File {
    group => $group_to_set,
  }

  $server_directory = $openvpn::server_directory

  ensure_resource('file', "${server_directory}/${name}", {
      ensure => directory,
      mode   => '0750'
  })

  file { "${server_directory}/${name}/easy-rsa" :
    ensure             => directory,
    recurse            => true,
    links              => 'follow',
    source_permissions => 'use',
    group              => 0,
    source             => "file:${openvpn::easyrsa_source}",
    require            => File["${server_directory}/${name}"],
  }

  file { "${server_directory}/${name}/easy-rsa/revoked":
    ensure  => directory,
    mode    => '0750',
    recurse => true,
    require => File["${server_directory}/${name}/easy-rsa"],
  }

  case $openvpn::easyrsa_version {
    '2.0': {
      file { "${server_directory}/${name}/easy-rsa/vars":
        ensure  => file,
        mode    => '0550',
        content => template('openvpn/vars.erb'),
        require => File["${server_directory}/${name}/easy-rsa"],
      }

      if $openvpn::link_openssl_cnf {
        File["${server_directory}/${name}/easy-rsa/openssl.cnf"] {
          ensure => link,
          target => "${server_directory}/${name}/easy-rsa/openssl-1.0.0.cnf",
          before => Exec["initca ${name}"],
        }
      }

      exec { "generate dh param ${name}":
        command  => '. ./vars && ./clean-all && ./build-dh',
        timeout  => 20000,
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/dh${ssl_key_size}.pem",
        provider => 'shell',
        require  => File["${server_directory}/${name}/easy-rsa/vars"],
      }

      exec { "initca ${name}":
        command  => '. ./vars && ./pkitool --initca',
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/ca.key",
        provider => 'shell',
        require  => Exec["generate dh param ${name}"],
      }

      exec { "generate server cert ${name}":
        command  => ". ./vars && ./pkitool --server ${common_name}",
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/${common_name}.key",
        provider => 'shell',
        require  => Exec["initca ${name}"],
      }

      exec { "create crl.pem on ${name}":
        command  => ". ./vars && KEY_CN='' KEY_OU='' KEY_NAME='' KEY_ALTNAMES='' openssl ca -gencrl -out ${server_directory}/${name}/crl.pem -config ${server_directory}/${name}/easy-rsa/openssl.cnf",
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/crl.pem",
        provider => 'shell',
        require  => Exec["generate server cert ${name}"],
      }
    }
    '3.0': {
      file { "${server_directory}/${name}/easy-rsa/vars":
        ensure  => file,
        mode    => '0550',
        content => epp('openvpn/vars-30.epp',
          {
            'server_directory' => $server_directory,
            'openvpn_server'   => $name,
            'ssl_key_size'     => $ssl_key_size,
            'ca_expire'        => $ca_expire,
            'key_expire'       => $key_expire,
            'crl_days'         => $crl_days,
            'country'          => $country,
            'province'         => $province,
            'city'             => $city,
            'organization'     => $organization,
            'email'            => $email,
            'key_cn'           => $key_cn,
            'key_ou'           => $key_ou,
          }
        ),
        require => File["${server_directory}/${name}/easy-rsa"],
      }

      if $openvpn::link_openssl_cnf {
        File["${server_directory}/${name}/easy-rsa/openssl.cnf"] {
          ensure => link,
          target => "${server_directory}/${name}/easy-rsa/openssl-1.0.cnf",
          before => Exec["initca ${name}"],
        }
      }

      exec { "initca ${name}":
        command  => './easyrsa --batch init-pki && ./easyrsa --batch build-ca nopass',
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/ca.crt",
        provider => 'shell',
        require  => File["${server_directory}/${name}/easy-rsa/vars"],
      }

      exec { "generate dh param ${name}":
        command  => './easyrsa --batch gen-dh',
        timeout  => 20000,
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/dh.pem",
        provider => 'shell',
        require  => Exec["generate server cert ${name}"],
      }

      exec { "generate server cert ${name}":
        command  => "./easyrsa build-server-full ${common_name} nopass",
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/easy-rsa/keys/private/${common_name}.key",
        provider => 'shell',
        require  => Exec["initca ${name}"],
      }

      file { "${server_directory}/${name}/easy-rsa/keys/ca.crt":
        mode    => '0640',
        require => Exec["initca ${name}"],
      }

      exec { "create crl.pem on ${name}":
        command  => ". ./vars && EASYRSA_REQ_CN='' EASYRSA_REQ_OU='' openssl ca -gencrl -out ${server_directory}/${name}/crl.pem -config ${server_directory}/${name}/easy-rsa/openssl.cnf",
        cwd      => "${server_directory}/${name}/easy-rsa",
        creates  => "${server_directory}/${name}/crl.pem",
        group    => $group_to_set,
        provider => 'shell',
        require  => Exec["generate server cert ${name}"],
      }
    }
    default: {
      fail("unexepected value for EasyRSA version, got '${openvpn::easyrsa_version}', expect 2.0 or 3.0.")
    }
  }

  file { "${server_directory}/${name}/easy-rsa/openssl.cnf":
    require => File["${server_directory}/${name}/easy-rsa"],
  }

  file { "${server_directory}/${name}/keys":
    ensure  => link,
    target  => "${server_directory}/${name}/easy-rsa/keys",
    mode    => '0640',
    require => File["${server_directory}/${name}/easy-rsa"],
  }

  file { "${server_directory}/${name}/crl.pem":
    mode    => '0640',
    require => Exec["create crl.pem on ${name}"],
  }

  if $tls_static_key {
    exec { "generate tls key for ${name}":
      command  => 'openvpn --genkey --secret keys/ta.key',
      cwd      => "${server_directory}/${name}/easy-rsa",
      creates  => "${server_directory}/${name}/easy-rsa/keys/ta.key",
      provider => 'shell',
      require  => Exec["generate server cert ${name}"],
    }
  }

  file { "${server_directory}/${name}/easy-rsa/keys/crl.pem":
    ensure  => link,
    target  => "${server_directory}/${name}/crl.pem",
    require => Exec["create crl.pem on ${name}"],
  }
}