Puppet Class: prometheus::blackbox_exporter

Inherits:
prometheus
Defined in:
manifests/blackbox_exporter.pp

Summary

This module manages prometheus blackbox_exporter

Overview

Example for configuring named blackbox modules via hiera details of the format: github.com/prometheus/blackbox_exporter/blob/master/CONFIGURATION.md prometheus::blackbox_exporter::modules:

simple_ssl:
  prober: http
  timeout: 10s
  http:
    fail_if_not_ssl: true
easy_tcp:
  prober: tcp
  tcp:
    preferred_ip_protocol: ip4

Parameters:

  • arch (String[1]) (defaults to: $prometheus::real_arch) —

    Architecture (amd64 or i386)

  • bin_dir (Stdlib::Absolutepath) (defaults to: $prometheus::bin_dir) —

    Directory where binaries are located

  • config_file (String[1]) —

    Absolute path to configuration file (blackbox module definitions)

  • download_extension (String) —

    Extension for the release binary archive

  • download_url (Optional[Prometheus::Uri]) (defaults to: undef) —

    Complete URL corresponding to the where the release binary archive can be downloaded

  • download_url_base (Prometheus::Uri) —

    Base URL for the binary archive

  • extra_groups (Array[String]) —

    Extra groups to add the binary user to

  • extra_options (Optional[String[1]]) (defaults to: undef) —

    Extra options added to the startup command

  • group (String[1]) —

    Group under which the binary is running

  • init_style (Prometheus::Initstyle) (defaults to: $facts['service_provider']) —

    Service startup scripts style (e.g. rc, upstart or systemd)

  • install_method (Prometheus::Install) (defaults to: $prometheus::install_method) —

    Installation method: url or package (only url is supported currently)

  • manage_group (Boolean) (defaults to: true) —

    Whether to create a group for or rely on external code for that

  • manage_service (Boolean) (defaults to: true) —

    Should puppet manage the service? (default true)

  • manage_user (Boolean) (defaults to: true) —

    Whether to create user or rely on external code for that

  • modules (Hash) (defaults to: {}) —

    Structured, array of blackbox module definitions for different probe types

  • os (String[1]) (defaults to: downcase($facts['kernel'])) —

    Operating system (linux is the only one supported)

  • package_ensure (String[1]) —

    If package, then use this for package ensure default ‘latest’

  • package_name (String[1]) —

    The binary package name - not available yet

  • restart_on_change (Boolean) (defaults to: true) —

    Should puppet restart the service on configuration change? (default true)

  • service_enable (Boolean) (defaults to: true) —

    Whether to enable the service from puppet (default true)

  • service_ensure (Stdlib::Ensure::Service) (defaults to: 'running') —

    State ensured for the service (default ‘running’)

  • service_name (String[1]) (defaults to: 'blackbox_exporter') —

    Name of the node exporter service (default ‘blackbox_exporter’)

  • user (String[1]) —

    User which runs the service

  • version (String[1]) —

    The binary release version

  • config_mode (String[1]) (defaults to: $prometheus::config_mode) —

    The permissions of the configuration files

  • proxy_server (Optional[String[1]]) (defaults to: undef) —

    Optional proxy server, with port number if needed. ie: example.com:8080

  • proxy_type (Optional[Enum['none', 'http', 'https', 'ftp']]) (defaults to: undef) —

    Optional proxy server type (none|http|https|ftp)

  • export_scrape_job (Boolean) (defaults to: false)
  • scrape_host (Optional[Stdlib::Host]) (defaults to: undef)
  • scrape_port (Stdlib::Port) (defaults to: 9115)
  • scrape_job_name (String[1]) (defaults to: 'blackbox')
  • scrape_job_labels (Optional[Hash]) (defaults to: undef) 


69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
 
# File 'manifests/blackbox_exporter.pp', line 69

class prometheus::blackbox_exporter (
  String[1] $config_file,
  String $download_extension,
  Prometheus::Uri $download_url_base,
  Array[String] $extra_groups,
  String[1] $group,
  String[1] $package_ensure,
  String[1] $package_name,
  String[1] $user,
  String[1] $version,
  Boolean $restart_on_change                                 = true,
  Boolean $service_enable                                    = true,
  Stdlib::Ensure::Service $service_ensure                    = 'running',
  String[1] $service_name                                    = 'blackbox_exporter',
  Prometheus::Initstyle $init_style                          = $facts['service_provider'],
  Prometheus::Install $install_method                        = $prometheus::install_method,
  Boolean $manage_group                                      = true,
  Boolean $manage_service                                    = true,
  Boolean $manage_user                                       = true,
  String[1] $os                                              = downcase($facts['kernel']),
  Optional[String[1]] $extra_options                         = undef,
  Optional[Prometheus::Uri] $download_url                    = undef,
  String[1] $config_mode                                     = $prometheus::config_mode,
  String[1] $arch                                            = $prometheus::real_arch,
  Stdlib::Absolutepath $bin_dir                              = $prometheus::bin_dir,
  Hash $modules                                              = {},
  Boolean $export_scrape_job                                 = false,
  Optional[Stdlib::Host] $scrape_host                        = undef,
  Stdlib::Port $scrape_port                                  = 9115,
  String[1] $scrape_job_name                                 = 'blackbox',
  Optional[Hash] $scrape_job_labels                          = undef,
  Optional[String[1]] $proxy_server                          = undef,
  Optional[Enum['none', 'http', 'https', 'ftp']] $proxy_type = undef,
) inherits prometheus {
  # Prometheus added a 'v' on the release name at 0.1.0 of blackbox
  if versioncmp ($version, '0.1.0') >= 0 {
    $release = "v${version}"
  }
  else {
    $release = $version
  }
  $real_download_url = pick($download_url,"${download_url_base}/download/${release}/${package_name}-${version}.${os}-${arch}.${download_extension}")
  $notify_service = $restart_on_change ? {
    true    => Service[$service_name],
    default => undef,
  }

  $options = "--config.file=${config_file} ${extra_options}"

  file { $config_file:
    ensure  => file,
    owner   => 'root',
    group   => $group,
    mode    => $config_mode,
    content => template('prometheus/blackbox_exporter.yaml.erb'),
    notify  => $notify_service,
  }

  prometheus::daemon { $service_name:
    install_method     => $install_method,
    version            => $version,
    download_extension => $download_extension,
    os                 => $os,
    arch               => $arch,
    real_download_url  => $real_download_url,
    bin_dir            => $bin_dir,
    notify_service     => $notify_service,
    package_name       => $package_name,
    package_ensure     => $package_ensure,
    manage_user        => $manage_user,
    user               => $user,
    extra_groups       => $extra_groups,
    group              => $group,
    manage_group       => $manage_group,
    options            => $options,
    init_style         => $init_style,
    service_ensure     => $service_ensure,
    service_enable     => $service_enable,
    manage_service     => $manage_service,
    export_scrape_job  => $export_scrape_job,
    scrape_host        => $scrape_host,
    scrape_port        => $scrape_port,
    scrape_job_name    => $scrape_job_name,
    scrape_job_labels  => $scrape_job_labels,
    proxy_server       => $proxy_server,
    proxy_type         => $proxy_type,
  }
}