Puppet Class: prometheus::rabbitmq_exporter
- Inherits:
- prometheus
- Defined in:
- manifests/rabbitmq_exporter.pp
Summary
This module manages prometheus rabbitmq_exporterOverview
This class is deprecated and will be removed in a future release.
Note:
84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 |
# File 'manifests/rabbitmq_exporter.pp', line 84
class prometheus::rabbitmq_exporter (
Prometheus::Uri $download_url_base,
Array[String] $extra_groups,
String[1] $group,
String[1] $package_ensure,
String[1] $package_name,
String[1] $service_name,
String $download_extension,
String[1] $user,
String[1] $rabbit_url,
String[1] $rabbit_user,
String[1] $rabbit_password,
String[1] $queues_include_regex,
String[1] $queues_exclude_regex,
Array[String] $rabbit_capabilities,
Array[String] $rabbit_exporters,
# renovate: depName=kbudde/rabbitmq_exporter
String[1] $version = '0.29.0',
String[1] $arch = $prometheus::real_arch,
Stdlib::Absolutepath $bin_dir = $prometheus::bin_dir,
Optional[Prometheus::Uri] $download_url = undef,
Optional[String[1]] $extra_options = undef,
Prometheus::Initstyle $init_style = $prometheus::init_style,
Prometheus::Install $install_method = $prometheus::install_method,
Boolean $manage_group = true,
Boolean $manage_service = true,
Boolean $manage_user = true,
String[1] $os = downcase($facts['kernel']),
Boolean $purge_config_dir = true,
Boolean $restart_on_change = true,
Boolean $service_enable = true,
Stdlib::Ensure::Service $service_ensure = 'running',
Hash[String,String] $extra_env_vars = {},
Boolean $export_scrape_job = false,
Optional[Stdlib::Host] $scrape_host = undef,
Stdlib::Port $scrape_port = 9419,
String[1] $scrape_job_name = 'rabbitmq',
Optional[Hash] $scrape_job_labels = undef,
Optional[String[1]] $proxy_server = undef,
Optional[Enum['none', 'http', 'https', 'ftp']] $proxy_type = undef,
) inherits prometheus {
deprecation(
'promtheus::rabbitmq_exporter',
'This class is deprecated and will be removed in a future release. See https://github.com/kbudde/rabbitmq_exporter/issues/383 for details',
false
)
if versioncmp($version, '1.0.0') >= 0 {
$extract_path = "/opt/${package_name}-${version}.${os}-${arch}"
$real_download_url = pick($download_url, "${download_url_base}/download/v${version}/${package_name}_${version}_${os}_${arch}.${download_extension}")
file { $extract_path:
ensure => 'directory',
owner => 'root',
group => 0, # 0 instead of root because OS X uses "wheel".
mode => '0555',
before => Prometheus::Daemon[$service_name],
}
} else {
$extract_path = '/opt'
$real_download_url = pick($download_url, "${download_url_base}/download/v${version}/${package_name}-${version}.${os}-${arch}.${download_extension}")
}
$notify_service = $restart_on_change ? {
true => Service[$service_name],
default => undef,
}
$env_vars = {
'RABBIT_URL' => $rabbit_url,
'RABBIT_USER' => $rabbit_user,
'RABBIT_PASSWORD' => $rabbit_password,
'INCLUDE_QUEUES' => $queues_include_regex,
'SKIP_QUEUES' => $queues_exclude_regex,
'RABBIT_CAPABILITIES' => join($rabbit_capabilities, ','),
'RABBIT_EXPORTERS' => join($rabbit_exporters, ','),
'PUBLISH_PORT' => $scrape_port,
}
$real_env_vars = stdlib::merge($env_vars, $extra_env_vars)
prometheus::daemon { $service_name:
install_method => $install_method,
version => $version,
download_extension => $download_extension,
os => $os,
arch => $arch,
real_download_url => $real_download_url,
bin_dir => $bin_dir,
notify_service => $notify_service,
package_name => $package_name,
package_ensure => $package_ensure,
manage_user => $manage_user,
user => $user,
extra_groups => $extra_groups,
group => $group,
manage_group => $manage_group,
purge => $purge_config_dir,
options => $extra_options,
init_style => $init_style,
service_ensure => $service_ensure,
service_enable => $service_enable,
manage_service => $manage_service,
env_vars => $real_env_vars,
export_scrape_job => $export_scrape_job,
scrape_host => $scrape_host,
scrape_port => $scrape_port,
scrape_job_name => $scrape_job_name,
scrape_job_labels => $scrape_job_labels,
proxy_server => $proxy_server,
proxy_type => $proxy_type,
extract_path => $extract_path,
}
}
|