Puppet Class: puppetboard::apache::conf

Defined in:
manifests/apache/conf.pp

Summary

Creates an entry in your apache configuration directory to run PuppetBoard server-wide (i.e. not in a vhost).

Overview

Note:

Make sure you have purge_configs set to false in your apache class!

Note:

This runs the WSGI application with a WSGIProcessGroup of $user and a WSGIApplicationGroup of %GLOBAL.

Parameters:

  • wsgi_alias (Stdlib::Unixpath) (defaults to: '/puppetboard') —

    WSGI script alias source

  • threads (Integer[1]) (defaults to: 5) —

    Number of WSGI threads to use

  • max_reqs (Integer[0]) (defaults to: 0) —

    Limit on number of requests allowed to daemon process Defaults to 0 (no limit)

  • user (String[1]) (defaults to: $puppetboard::user) —

    WSGI daemon process user, and daemon process name

  • group (String[1]) (defaults to: $puppetboard::group) —

    WSGI daemon process group owner, and daemon process group

  • basedir (Stdlib::AbsolutePath) (defaults to: $puppetboard::basedir) —

    Base directory where to build puppetboard vcsrepo and python virtualenv.

  • enable_ldap_auth (Boolean) (defaults to: $puppetboard::enable_ldap_auth) —

    Whether to enable LDAP auth

  • ldap_bind_dn (Optional[String[1]]) (defaults to: undef) —

    LDAP Bind DN

  • ldap_bind_password (Optional[String[1]]) (defaults to: undef) —

    LDAP password

  • ldap_url (Optional[String[1]]) (defaults to: undef) —

    LDAP connection string

  • ldap_bind_authoritative (Optional[String[1]]) (defaults to: undef) —

    Determines if other authentication providers are used when a user can be mapped to a DN but the server cannot bind with the credentials

  • ldap_require_group (Boolean) (defaults to: $puppetboard::ldap_require_group) —

    LDAP group to require on login

  • ldap_require_group_dn (Optional[String[1]]) (defaults to: undef) —

    LDAP group DN for LDAP group

  • ldap_require_user (Optional[String[1]]) (defaults to: undef) —

    if set, list of uids for Require ldap-user directive

  • ldap_require_dn (Optional[String[1]]) (defaults to: undef) —

    if set, dn to be matched by Require ldap-dn directive

  • ldap_require_attribute (Optional[String[1]]) (defaults to: undef) —

    if set, attributes of LDAP users for Require ldap-attribute directive

  • ldap_require_filter (Optional[String[1]]) (defaults to: undef) —

    if set, LDAP search filter for Require ldap-filter directive

  • virtualenv_dir (Stdlib::Absolutepath) (defaults to: $puppetboard::virtualenv_dir) —

    Set location where virtualenv will be installed



25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
 
# File 'manifests/apache/conf.pp', line 25

class puppetboard::apache::conf (
  Stdlib::Unixpath $wsgi_alias                 = '/puppetboard',
  Integer[1] $threads                          = 5,
  Integer[0] $max_reqs                         = 0,
  String[1] $user                              = $puppetboard::user,
  String[1] $group                             = $puppetboard::group,
  Stdlib::AbsolutePath $basedir                = $puppetboard::basedir,
  Boolean $enable_ldap_auth                    = $puppetboard::enable_ldap_auth,
  Optional[String[1]] $ldap_bind_dn            = undef,
  Optional[String[1]] $ldap_bind_password      = undef,
  Optional[String[1]] $ldap_url                = undef,
  Optional[String[1]] $ldap_bind_authoritative = undef,
  Boolean $ldap_require_group                  = $puppetboard::ldap_require_group,
  Optional[String[1]] $ldap_require_group_dn   = undef,
  Optional[String[1]] $ldap_require_user          = undef,
  Optional[String[1]] $ldap_require_dn            = undef,
  Optional[String[1]] $ldap_require_attribute     = undef,
  Optional[String[1]] $ldap_require_filter        = undef,
  Stdlib::Absolutepath $virtualenv_dir         = $puppetboard::virtualenv_dir,
) {
  $wsgi = $facts['os']['family'] ? {
    'Debian' => {
      package_name => 'libapache2-mod-wsgi-py3',
      mod_path     => '/usr/lib/apache2/modules/mod_wsgi.so',
    },
    default  => {},
  }
  class { 'apache::mod::wsgi':
    * => $wsgi,
  }

  $docroot = "${basedir}/puppetboard"

  file { "${puppetboard::apache_confd}/puppetboard.conf":
    ensure => absent,
  }
  -> file { "${docroot}/wsgi.py":
    ensure  => file,
    content => file("${module_name}/wsgi.py"),
    owner   => $user,
    group   => $group,
  }
  -> apache::custom_config { 'puppetboard':
    ensure  => present,
    owner   => 'root',
    group   => 'root',
    content => epp("${module_name}/apache/conf.epp",
      {
        'docroot'                 => $docroot,
        'enable_ldap_auth'        => $enable_ldap_auth,
        'group'                   => $group,
        'ldap_bind_authoritative' => $ldap_bind_authoritative,
        'ldap_bind_dn'            => $ldap_bind_dn,
        'ldap_bind_password'      => $ldap_bind_password,
        'ldap_require_group_dn'   => $ldap_require_group_dn,
        'ldap_require_group'      => $ldap_require_group,
        'ldap_require_user'       => $ldap_require_user,
        'ldap_require_dn'         => $ldap_require_dn,
        'ldap_require_attribute'  => $ldap_require_attribute,
        'ldap_require_filter'     => $ldap_require_filter,
        'ldap_url'                => $ldap_url,
        'max_reqs'                => $max_reqs,
        'threads'                 => $threads,
        'user'                    => $user,
        'virtualenv_dir'          => $virtualenv_dir,
        'wsgi_alias'              => $wsgi_alias,
      },
    ),
  }
}