182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
|
# File 'manifests/user.pp', line 182
define accounts::user (
Enum['absent','present'] $ensure = 'present',
Boolean $allowdupe = false,
Optional[String] $bash_profile_content = undef,
Optional[Stdlib::Filesource] $bash_profile_source = undef,
Optional[String] $bashrc_content = undef,
Optional[Stdlib::Filesource] $bashrc_source = undef,
String $comment = $name,
Boolean $create_group = true,
Optional[Accounts::User::Expiry] $expiry = undef,
Optional[Boolean] $forcelocal = undef,
Optional[String] $forward_content = undef,
Optional[Stdlib::Filesource] $forward_source = undef,
Optional[Accounts::User::Uid] $gid = undef,
Accounts::User::Name $group = $name,
Array[Accounts::User::Name] $groups = [],
Optional[Stdlib::Unixpath] $home = undef,
Optional[Stdlib::Filemode] $home_mode = undef,
Boolean $ignore_password_if_empty = false,
Optional[Accounts::User::Iterations] $iterations = undef,
Boolean $locked = false,
Boolean $managehome = true,
Boolean $managevim = true,
Enum['inclusive','minimum'] $membership = 'minimum',
Variant[String, Sensitive[String]] $password = '!!',
Optional[Accounts::User::PasswordMaxAge] $password_max_age = undef,
Boolean $purge_sshkeys = false,
Boolean $purge_user_home = false,
Optional[String] $salt = undef,
Stdlib::Unixpath $shell = '/bin/bash',
Optional[Stdlib::Unixpath] $sshkey_custom_path = undef,
Optional[Accounts::User::Name] $sshkey_group = $group,
Optional[Accounts::User::Name] $sshkey_owner = $name,
Variant[Integer[0],String] $sshkey_mode = '0600',
Array[String] $sshkeys = [],
Boolean $system = false,
Optional[Accounts::User::Uid] $uid = undef,
) {
assert_type(Accounts::User::Name, $name)
include accounts::user::defaults
$_home = $home ? {
undef => $name ? {
'root' => $accounts::user::defaults::root_home,
default => $accounts::user::defaults::home_template.sprintf($name),
},
default => $home,
}
if $ensure == 'absent' {
user { $name:
ensure => 'absent',
forcelocal => $forcelocal,
home => $_home,
managehome => false, # Workaround for PUP-9706; see below.
}
# The core `user` resource will fail when removing users on Solaris if
# `ensure => 'absent', managhome => true` and the homedir does not exist.
# We therefore force `managehome => false` when `ensure => 'absent'`, and
# remove the homedir as a separate operation.
# See https://tickets.puppetlabs.com/browse/PUP-9706
if $purge_user_home {
file { $_home:
ensure => 'absent',
recurse => true,
force => true,
}
}
# End workaround.
User[$name] -> Group <| ensure == 'absent' |>
if $create_group {
# Only remove the group if it is the same as user name as it may be shared.
if $name == $group {
ensure_resource(
'group',
$group,
{ 'ensure' => 'absent',
'forcelocal' => $forcelocal,
}
)
}
}
accounts::key_management { "${name}_key_management":
ensure => 'absent',
user => $name,
user_home => $_home,
sshkeys => $sshkeys,
sshkey_custom_path => $sshkey_custom_path,
sshkey_owner => $sshkey_owner,
sshkey_group => $sshkey_group,
sshkey_mode => $sshkey_mode,
purge_user_home => $purge_user_home,
}
} else {
# Check if user wants to create the group
if $create_group and ! defined(Group[$group]) {
Group[$group] -> User[$name]
ensure_resource(
'group',
$group,
{ ensure => 'present',
gid => $gid,
system => $system,
forcelocal => $forcelocal,
}
)
}
$_password = (($password =~ String and $password == '') and $ignore_password_if_empty) ? {
true => undef,
default => $password,
}
$_purge_sshkeys = ($purge_sshkeys and $sshkey_custom_path != undef) ? {
true => [String($sshkey_custom_path)],
default => $purge_sshkeys,
}
$_shell = $locked ? {
true => $accounts::user::defaults::locked_shell,
default => $shell,
}
user { $name:
ensure => 'present',
allowdupe => $allowdupe,
comment => String($comment),
expiry => $expiry,
forcelocal => $forcelocal,
gid => $group,
groups => $groups,
home => $_home,
iterations => $iterations,
managehome => $managehome,
membership => $membership,
password => $_password,
password_max_age => $password_max_age,
purge_ssh_keys => $_purge_sshkeys,
salt => $salt,
shell => $_shell,
system => $system,
uid => $uid,
}
if $managehome {
accounts::home_dir { $_home:
ensure => 'present',
mode => $home_mode,
managevim => $managevim,
bashrc_content => $bashrc_content,
bashrc_source => $bashrc_source,
bash_profile_content => $bash_profile_content,
bash_profile_source => $bash_profile_source,
forward_content => $forward_content,
forward_source => $forward_source,
user => $name,
group => $group,
require => [User[$name]],
}
accounts::key_management { "${name}_key_management":
ensure => 'present',
user => $name,
group => $group,
user_home => $_home,
sshkeys => $sshkeys,
sshkey_custom_path => $sshkey_custom_path,
sshkey_owner => $sshkey_owner,
sshkey_group => $sshkey_group,
sshkey_mode => $sshkey_mode,
purge_user_home => $purge_user_home,
require => Accounts::Home_dir[$_home],
}
} elsif $sshkeys != [] {
# We are not managing the user's home directory but we have specified a
# custom, non-home directory for the ssh keys.
if (($sshkey_custom_path != undef) and ($ensure == 'present')) {
accounts::key_management { "${name}_key_management":
ensure => 'present',
user => $name,
group => $group,
sshkeys => $sshkeys,
sshkey_owner => $sshkey_owner,
sshkey_group => $sshkey_group,
sshkey_mode => $sshkey_mode,
sshkey_custom_path => $sshkey_custom_path,
}
} else {
warning("ssh keys were passed for user ${name} but managehome is set to false; not managing user ssh keys")
}
}
}
}
|