Puppet Class: apache::mod::userdir

Defined in:
manifests/mod/userdir.pp

Summary

Installs and configures `mod_userdir`.

Overview

Parameters:

  • home (Any) (defaults to: undef) —

    Deprecated Path to system home directory.

  • dir (Any) (defaults to: undef) —

    Deprecated Path from user’s home directory to public directory.

  • disable_root (Any) (defaults to: true) —

    Toggles whether to allow use of root directory.

  • apache_version (Any) (defaults to: undef) —

    Used to verify that the Apache version you have requested is compatible with the module.

  • path (Any) (defaults to: '/home/*/public_html') —

    Path to directory or pattern from which to find user-specific directories.

  • overrides (Any) (defaults to: [ 'FileInfo', 'AuthConfig', 'Limit', 'Indexes' ]) —

    Array of directives that are allowed in .htaccess files.

  • options (Any) (defaults to: [ 'MultiViews', 'Indexes', 'SymLinksIfOwnerMatch', 'IncludesNoExec' ]) —

    Configures what features are available in a particular directory.

  • unmanaged_path (Any) (defaults to: false) —

    Toggles whether to manage path in userdir.conf

  • custom_fragment (Any) (defaults to: undef) —

    Custom configuration to be added to userdir.conf

See Also:



33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
 
# File 'manifests/mod/userdir.pp', line 33

class apache::mod::userdir (
  $home = undef,
  $dir = undef,
  $disable_root = true,
  $apache_version = undef,
  $path = '/home/*/public_html',
  $overrides = [ 'FileInfo', 'AuthConfig', 'Limit', 'Indexes' ],
  $options = [ 'MultiViews', 'Indexes', 'SymLinksIfOwnerMatch', 'IncludesNoExec' ],
  $unmanaged_path = false,
  $custom_fragment = undef,
) {
  include ::apache
  $_apache_version = pick($apache_version, $apache::apache_version)

  if $home or $dir {
    $_home = $home ? {
      undef   => '/home',
      default =>  $home,
    }
    $_dir = $dir ? {
      undef   => 'public_html',
      default =>  $dir,
    }
    warning('home and dir are deprecated; use path instead')
    $_path = "${_home}/*/${_dir}"
  } else {
    $_path = $path
  }

  ::apache::mod { 'userdir': }

  # Template uses $home, $dir, $disable_root, $_apache_version
  file { 'userdir.conf':
    ensure  => file,
    path    => "${::apache::mod_dir}/userdir.conf",
    mode    => $::apache::file_mode,
    content => template('apache/mod/userdir.conf.erb'),
    require => Exec["mkdir ${::apache::mod_dir}"],
    before  => File[$::apache::mod_dir],
    notify  => Class['apache::service'],
  }
}