Puppet Class: apt

Inherits:
apt::params
Defined in:
manifests/init.pp

Overview

Class: apt

Manage APT (Advanced Packaging Tool)

Parameters:

  • update_defaults (Hash) (defaults to: $apt::params::update_defaults)
  • purge_defaults (Hash) (defaults to: $apt::params::purge_defaults)
  • proxy_defaults (Hash) (defaults to: $apt::params::proxy_defaults)
  • include_defaults (Hash) (defaults to: $apt::params::include_defaults)
  • provider (String) (defaults to: $apt::params::provider)
  • keyserver (String) (defaults to: $apt::params::keyserver)
  • ppa_options (Optional[String]) (defaults to: $apt::params::ppa_options)
  • ppa_package (Optional[String]) (defaults to: $apt::params::ppa_package)
  • backports (Optional[Hash]) (defaults to: $apt::params::backports)
  • confs (Hash) (defaults to: $apt::params::confs)
  • update (Hash) (defaults to: $apt::params::update)
  • purge (Hash) (defaults to: $apt::params::purge)
  • proxy (Hash) (defaults to: $apt::params::proxy)
  • sources (Hash) (defaults to: $apt::params::sources)
  • keys (Hash) (defaults to: $apt::params::keys)
  • ppas (Hash) (defaults to: $apt::params::ppas)
  • pins (Hash) (defaults to: $apt::params::pins)
  • settings (Hash) (defaults to: $apt::params::settings)
  • auth_conf_entries (Array[Apt::Auth_conf_entry]) (defaults to: $apt::params::auth_conf_entries)
  • root (String) (defaults to: $apt::params::root)
  • sources_list (String) (defaults to: $apt::params::sources_list)
  • sources_list_d (String) (defaults to: $apt::params::sources_list_d)
  • conf_d (String) (defaults to: $apt::params::conf_d)
  • preferences (String) (defaults to: $apt::params::preferences)
  • preferences_d (String) (defaults to: $apt::params::preferences_d)
  • config_files (Hash) (defaults to: $apt::params::config_files)
  • source_key_defaults (Hash) (defaults to: $apt::params::source_key_defaults) 


5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
 
# File 'manifests/init.pp', line 5

class apt (
  Hash $update_defaults         = $apt::params::update_defaults,
  Hash $purge_defaults          = $apt::params::purge_defaults,
  Hash $proxy_defaults          = $apt::params::proxy_defaults,
  Hash $include_defaults        = $apt::params::include_defaults,
  String $provider              = $apt::params::provider,
  String $keyserver             = $apt::params::keyserver,
  Optional[String] $ppa_options = $apt::params::ppa_options,
  Optional[String] $ppa_package = $apt::params::ppa_package,
  Optional[Hash] $backports     = $apt::params::backports,
  Hash $confs                   = $apt::params::confs,
  Hash $update                  = $apt::params::update,
  Hash $purge                   = $apt::params::purge,
  Hash $proxy                   = $apt::params::proxy,
  Hash $sources                 = $apt::params::sources,
  Hash $keys                    = $apt::params::keys,
  Hash $ppas                    = $apt::params::ppas,
  Hash $pins                    = $apt::params::pins,
  Hash $settings                = $apt::params::settings,
  Array[Apt::Auth_conf_entry]
    $auth_conf_entries          = $apt::params::auth_conf_entries,
  String $root                  = $apt::params::root,
  String $sources_list          = $apt::params::sources_list,
  String $sources_list_d        = $apt::params::sources_list_d,
  String $conf_d                = $apt::params::conf_d,
  String $preferences           = $apt::params::preferences,
  String $preferences_d         = $apt::params::preferences_d,
  Hash $config_files            = $apt::params::config_files,
  Hash $source_key_defaults     = $apt::params::source_key_defaults
) inherits apt::params {

  if $facts['osfamily'] != 'Debian' {
    fail('This module only works on Debian or derivatives like Ubuntu')
  }

  if $update['frequency'] {
    assert_type(
      Enum['always','daily','weekly','reluctantly'],
      $update['frequency'],
    )
  }
  if $update['timeout'] {
    assert_type(Integer, $update['timeout'])
  }
  if $update['tries'] {
    assert_type(Integer, $update['tries'])
  }

  $_update = merge($::apt::update_defaults, $update)
  include ::apt::update

  if $purge['sources.list'] {
    assert_type(Boolean, $purge['sources.list'])
  }
  if $purge['sources.list.d'] {
    assert_type(Boolean, $purge['sources.list.d'])
  }
  if $purge['preferences'] {
    assert_type(Boolean, $purge['preferences'])
  }
  if $purge['preferences.d'] {
    assert_type(Boolean, $purge['preferences.d'])
  }

  $_purge = merge($::apt::purge_defaults, $purge)

  if $proxy['ensure'] {
    assert_type(Enum['file', 'present', 'absent'], $proxy['ensure'])
  }
  if $proxy['host'] {
    assert_type(String, $proxy['host'])
  }
  if $proxy['port'] {
    assert_type(Integer, $proxy['port'])
  }
  if $proxy['https']{
    assert_type(Boolean, $proxy['https'])
  }
  if $proxy['direct']{
    assert_type(Boolean, $proxy['direct'])
  }

  $_proxy = merge($apt::proxy_defaults, $proxy)

  $confheadertmp = epp('apt/_conf_header.epp')
  $proxytmp = epp('apt/proxy.epp', {'proxies' => $_proxy})
  $updatestamptmp = epp('apt/15update-stamp.epp')

  if $_proxy['ensure'] == 'absent' or $_proxy['host'] {
    apt::setting { 'conf-proxy':
      ensure   => $_proxy['ensure'],
      priority => '01',
      content  => "${confheadertmp}${proxytmp}",
    }
  }

  $sources_list_content = $_purge['sources.list'] ? {
    true    => "# Repos managed by puppet.\n",
    default => undef,
  }

  $preferences_ensure = $_purge['preferences'] ? {
    true    => absent,
    default => file,
  }

  if $_update['frequency'] == 'always' {
    Exec <| title=='apt_update' |> {
      refreshonly => false,
    }
  }

  apt::setting { 'conf-update-stamp':
    priority => 15,
    content  => "${confheadertmp}${updatestamptmp}",
  }

  file { 'sources.list':
    ensure  => file,
    path    => $::apt::sources_list,
    owner   => root,
    group   => root,
    mode    => '0644',
    content => $sources_list_content,
    notify  => Class['apt::update'],
  }

  file { 'sources.list.d':
    ensure  => directory,
    path    => $::apt::sources_list_d,
    owner   => root,
    group   => root,
    mode    => '0644',
    purge   => $_purge['sources.list.d'],
    recurse => $_purge['sources.list.d'],
    notify  => Class['apt::update'],
  }

  file { 'preferences':
    ensure => $preferences_ensure,
    path   => $::apt::preferences,
    owner  => root,
    group  => root,
    mode   => '0644',
    notify => Class['apt::update'],
  }

  file { 'preferences.d':
    ensure  => directory,
    path    => $::apt::preferences_d,
    owner   => root,
    group   => root,
    mode    => '0644',
    purge   => $_purge['preferences.d'],
    recurse => $_purge['preferences.d'],
    notify  => Class['apt::update'],
  }

  if $confs {
    create_resources('apt::conf', $confs)
  }
  # manage sources if present
  if $sources {
    create_resources('apt::source', $sources)
  }
  # manage keys if present
  if $keys {
    create_resources('apt::key', $keys)
  }
  # manage ppas if present
  if $ppas {
    create_resources('apt::ppa', $ppas)
  }
  # manage settings if present
  if $settings {
    create_resources('apt::setting', $settings)
  }

  $auth_conf_ensure = $auth_conf_entries ? {
    []      => 'absent',
    default => 'present',
  }

  $auth_conf_tmp = epp('apt/auth_conf.epp')

  file { '/etc/apt/auth.conf':
    ensure  => $auth_conf_ensure,
    owner   => 'root',
    group   => 'root',
    mode    => '0600',
    content => "${confheadertmp}${auth_conf_tmp}",
    notify  => Class['apt::update'],
  }

  # manage pins if present
  if $pins {
    create_resources('apt::pin', $pins)
  }

  # required for adding GPG keys on Debian 9 (and derivatives)
  ensure_packages(['dirmngr'])
}