Puppet Class: cd4peadm::component::query

Defined in:
manifests/component/query.pp

Summary

installs and configures the query service component which is used by the estate reporting feature.

Overview

Parameters:

  • config (Cd4peadm::Config::Query) —

    subset of Cd4peadm::Config specific to the query service.

  • api_container_name (String) —

    name of container the query service relies on for PE information



6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
# File 'manifests/component/query.pp', line 6

class cd4peadm::component::query (
  Cd4peadm::Config::Query $config,
  String $api_container_name
) {
  include cd4peadm::log_rotation

  $container = $config['container']
  cd4peadm::runtime::volume { $container['log_volume_name']:
    ensure  => present,
    runtime => $config['runtime'],
  }

  $env_data = {
    api_container_name => $api_container_name,
    log_level => $config['log_level'],
    db_username => $config['db_username'],
    db_password => $config['db_password'],
    db_endpoint => $config['db_endpoint'],
    env_vars => $config['env_vars'],
  }

  file { '/etc/puppetlabs/cd4pe/query_env':
    ensure    => file,
    owner     => 'root',
    group     => 'root',
    seltype   => 'container_file_t',
    show_diff => false,
    content   => epp('cd4peadm/query_env.epp', $env_data),
    notify    => Cd4peadm::Runtime::Run[$container['name']],
  }

  cd4peadm::runtime::run { $container['name']:
    runtime          => $config['runtime'],
    image            => $container['image'],
    extra_parameters => $container['extra_parameters'],
    net              => 'cd4pe',
    pull_on_start    => false,
    env_file         => ['/etc/puppetlabs/cd4pe/query_env'],
    volumes          => [
      "${container['log_volume_name']}:/app/logs",
      'cd4pe-query-service-token:/etc/puppetlabs/cd4pe',
    ],
  }

  cd4peadm::logrotate_config { 'query':
    path            => "${cd4peadm::runtime::volume_dir()}/${container['log_volume_name']}/_data/*.log",
    size_mb         => $config['max_log_size_mb'],
    post_rotate_cmd => "${config['runtime']} kill ${container['name']} -s SIGUSR1",
    keep_files      => $config['keep_log_files'],
  }
}