Puppet Class: docker::install

Defined in:
manifests/install.pp

Summary

Module to install an up-to-date version of Docker from a package repository. Only for Debian, Red Hat and Windows

Overview

Parameters:

  • version (Optional[String]) (defaults to: $docker::version) —

    The package version to install, used to set the package name.

  • nuget_package_provider_version (Optional[String]) (defaults to: $docker::nuget_package_provider_version) —

    The version of the NuGet Package provider

  • docker_msft_provider_version (Optional[String]) (defaults to: $docker::docker_msft_provider_version) —

    The version of the Microsoft Docker Provider Module

  • docker_ee_package_name (Optional[String]) (defaults to: $docker::docker_ee_package_name) —

    The name of the Docker Enterprise Edition package

  • docker_download_url (Optional[String]) (defaults to: $docker::package_location)
  • dependent_packages (Array) (defaults to: $docker::dependent_packages) 


21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
 
# File 'manifests/install.pp', line 21

class docker::install (
  Optional[String] $version                        = $docker::version,
  Optional[String] $nuget_package_provider_version = $docker::nuget_package_provider_version,
  Optional[String] $docker_msft_provider_version   = $docker::docker_msft_provider_version,
  Optional[String] $docker_ee_package_name         = $docker::docker_ee_package_name,
  Optional[String] $docker_download_url            = $docker::package_location,
  Array            $dependent_packages             = $docker::dependent_packages,
) {
  $docker_start_command = $docker::docker_start_command

  if $facts['os']['family'] and ! $docker::acknowledge_unsupported_os {
    assert_type(Pattern[/^(Debian|RedHat|windows)$/], $facts['os']['family']) |$a, $b| {
      fail('This module only works on Debian, RedHat or Windows.')
    }
  }
  if $docker::version and $docker::ensure != 'absent' {
    $ensure = $docker::version
  } else {
    $ensure = $docker::ensure
  }

  if $docker::manage_package {
    if empty($docker::repo_opt) {
      $docker_hash = {}
    } else {
      $docker_hash = { 'install_options' => $docker::repo_opt }
    }

    if $docker::package_source {
      if $facts['os']['family'] == 'windows' {
        fail('Custom package source is currently not implemented on windows.')
      }
      case $docker::package_source {
        /docker-engine/ : {
          ensure_resource('package', 'docker', stdlib::merge($docker_hash, {
                ensure => $ensure,
                source => $docker::package_source,
                name   => $docker::docker_engine_package_name,
          }))
        }
        /docker-ce/ : {
          ensure_resource('package', 'docker', stdlib::merge($docker_hash, {
                ensure => $ensure,
                source => $docker::package_source,
                name   => $docker::docker_ce_package_name,
          }))
          ensure_resource('package', 'docker-ce-cli', stdlib::merge($docker_hash, {
                ensure => $ensure,
                source => $docker::package_source,
                name   => $docker::docker_ce_cli_package_name,
          }))
        }
        default : {
          # Empty
        }
      }
    } else {
      if $facts['os']['family'] != 'windows' {
        ensure_resource('package', 'docker', stdlib::merge($docker_hash, {
              ensure => $ensure,
              name   => $docker::docker_package_name,
        }))

        if $ensure == 'absent' {
          ensure_resource('package', $dependent_packages, {
              ensure => $ensure,
          })
        }
      } else {
        if $ensure == 'absent' {
          exec { 'remove-docker-package':
            command   => template('docker/windows/remove_docker.ps1.erb'),
            provider  => powershell,
            unless    => template('docker/windows/check_docker.ps1.erb'),
            logoutput => true,
          }
        } else {
          if $docker::package_location {
            exec { 'install-docker-package':
              command   => template('docker/windows/download_docker.ps1.erb'),
              provider  => powershell,
              unless    => template('docker/windows/check_docker_url.ps1.erb'),
              logoutput => true,
              notify    => Exec['service-restart-on-failure'],
            }
          } else {
            exec { 'install-docker-package':
              command   => template('docker/windows/install_powershell_provider.ps1.erb'),
              provider  => powershell,
              unless    => template('docker/windows/check_powershell_provider.ps1.erb'),
              logoutput => true,
              timeout   => 1800,
              notify    => Exec['service-restart-on-failure'],
            }
          }

          exec { 'service-restart-on-failure':
            command     => 'SC.exe failure Docker reset= 432000 actions= restart/30000/restart/60000/restart/60000',
            refreshonly => true,
            logoutput   => true,
            provider    => powershell,
          }
        }
      }
    }
  }
}