Puppet Class: mcollective::middleware::activemq

Defined in:
manifests/middleware/activemq.pp

Overview

private class



2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
# File 'manifests/middleware/activemq.pp', line 2

class mcollective::middleware::activemq {
  if $caller_module_name != $module_name {
    fail("Use of private class ${name} by ${caller_module_name}")
  }

  if $mcollective::activemq_config {
    $server_config = $mcollective::activemq_config
  }
  else {
    $server_config = template($mcollective::activemq_template)
  }

  anchor { 'mcollective::middleware::activemq::begin': } ->
  class { '::activemq':
    instance      => 'mcollective',
    server_config => $server_config,
  } ->
  anchor { 'mcollective::middleware::activemq::end': }

  if $mcollective::middleware_ssl {
    Class['activemq::packages'] ->

    file { "${mcollective::activemq_confdir}/ca.pem":
      owner  => 'activemq',
      group  => 'activemq',
      mode   => '0444',
      source => $mcollective::ssl_ca_cert,
    } ->

    java_ks { 'mcollective:truststore':
      ensure       => 'latest',
      certificate  => "${mcollective::activemq_confdir}/ca.pem",
      target       => "${mcollective::activemq_confdir}/truststore.jks",
      password     => 'puppet',
      trustcacerts => true,
    } ->

    file { "${mcollective::activemq_confdir}/truststore.jks":
      owner => 'activemq',
      group => 'activemq',
      mode  => '0400',
    } ->

    file { "${mcollective::activemq_confdir}/server_public.pem":
      owner  => 'activemq',
      group  => 'activemq',
      mode   => '0444',
      source => $mcollective::ssl_server_public,
    } ->

    file { "${mcollective::activemq_confdir}/server_private.pem":
      owner  => 'activemq',
      group  => 'activemq',
      mode   => '0400',
      source => $mcollective::ssl_server_private,
    } ->

    java_ks { 'mcollective:keystore':
      ensure       => 'latest',
      certificate  => "${mcollective::activemq_confdir}/server_public.pem",
      private_key  => "${mcollective::activemq_confdir}/server_private.pem",
      target       => "${mcollective::activemq_confdir}/keystore.jks",
      password     => 'puppet',
      trustcacerts => true,
    } ->

    file { "${mcollective::activemq_confdir}/keystore.jks":
      owner => 'activemq',
      group => 'activemq',
      mode  => '0400',
    } ->

    Class['activemq::service']
  }
}