Puppet Class: mysql::server::account_security

Defined in:
manifests/server/account_security.pp

Summary

Private class for ensuring localhost accounts do not exist

Overview



6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
# File 'manifests/server/account_security.pp', line 6

class mysql::server::account_security {
  mysql_user {
    ['root@127.0.0.1',
      'root@::1',
      '@localhost',
    '@%']:
      ensure  => 'absent',
      require => Anchor['mysql::server::end'],
  }
  if ($facts['networking']['fqdn'] != 'localhost.localdomain') {
    mysql_user {
      ['root@localhost.localdomain',
      '@localhost.localdomain']:
        ensure  => 'absent',
        require => Anchor['mysql::server::end'],
    }
  }
  if ($facts['networking']['fqdn'] and $facts['networking']['fqdn'] != 'localhost') {
    mysql_user {
      ["root@${facts['networking']['fqdn']}",
      "@${facts['networking']['fqdn']}"]:
        ensure  => 'absent',
        require => Anchor['mysql::server::end'],
    }
  }
  if ($facts['networking']['fqdn'] != $facts['networking']['hostname']) {
    if ($facts['networking']['hostname'] != 'localhost') {
      mysql_user { ["root@${facts['networking']['hostname']}", "@${facts['networking']['hostname']}"]:
        ensure  => 'absent',
        require => Anchor['mysql::server::end'],
      }
    }
  }
  mysql_database { 'test':
    ensure  => 'absent',
    require => Anchor['mysql::server::end'],
  }
}