Puppet Class: passenger

Inherits:
passenger::params
Defined in:
manifests/init.pp

Overview

Class: passenger

This class installs Passenger (mod_rails) on your system. www.modrails.com

Parameters:

[*passenger_version*]
  The Version of Passenger to be installed

[*gem_path*]
  The path to rubygems on your system

[*gem_binary_path*]
  Path to Rubygems binaries on your system

[*mod_passenger_location*]
  Path to Passenger's mod_passenger.so file

[*passenger_provider*]
  The package provider to use for the system

[*passenger_package*]
  The name of the Passenger package

Usage:

class { 'passenger':
  passenger_version      => '3.0.9',
  passenger_ruby         => '/usr/bin/ruby'
  gem_path               => '/var/lib/gems/1.8/gems',
  gem_binary_path        => '/var/lib/gems/1.8/bin',
  mod_passenger_location => '/var/lib/gems/1.8/gems/passenger-3.0.9/ext/apache2/mod_passenger.so',
  passenger_provider     => 'gem',
  passenger_package      => 'passenger',
}

Requires:

- apache
- apache::dev

Parameters:

  • passenger_version (Any) (defaults to: $passenger::params::passenger_version)
  • passenger_ruby (Any) (defaults to: $passenger::params::passenger_ruby)
  • gem_path (Any) (defaults to: $passenger::params::gem_path)
  • gem_binary_path (Any) (defaults to: $passenger::params::gem_binary_path)
  • mod_passenger_location (Any) (defaults to: $passenger::params::mod_passenger_location)
  • passenger_provider (Any) (defaults to: $passenger::params::passenger_provider)
  • passenger_package (Any) (defaults to: $passenger::params::passenger_package) 


42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
 
# File 'manifests/init.pp', line 42

class passenger (
  $passenger_version      = $passenger::params::passenger_version,
  $passenger_ruby         = $passenger::params::passenger_ruby,
  $gem_path               = $passenger::params::gem_path,
  $gem_binary_path        = $passenger::params::gem_binary_path,
  $mod_passenger_location = $passenger::params::mod_passenger_location,
  $passenger_provider     = $passenger::params::passenger_provider,
  $passenger_package      = $passenger::params::passenger_package
) inherits passenger::params {

  include apache
  require apache::dev

  case $::osfamily {
    'debian': {
      package { [$passenger::params::libruby, 'libcurl4-openssl-dev']:
        ensure => present,
        before => Exec['compile-passenger'],
      }

      file { '/etc/apache2/mods-available/passenger.load':
        ensure  => present,
        content => template('passenger/passenger-load.erb'),
        owner   => '0',
        group   => '0',
        mode    => '0644',
        notify  => Service['httpd'],
      }

      file { '/etc/apache2/mods-available/passenger.conf':
        ensure  => present,
        content => template('passenger/passenger-enabled.erb'),
        owner   => '0',
        group   => '0',
        mode    => '0644',
        notify  => Service['httpd'],
      }

      file { '/etc/apache2/mods-enabled/passenger.load':
        ensure  => 'link',
        target  => '/etc/apache2/mods-available/passenger.load',
        owner   => '0',
        group   => '0',
        mode    => '0777',
        require => [ File['/etc/apache2/mods-available/passenger.load'], Exec['compile-passenger'], ],
        notify  => Service['httpd'],
      }

      file { '/etc/apache2/mods-enabled/passenger.conf':
        ensure  => 'link',
        target  => '/etc/apache2/mods-available/passenger.conf',
        owner   => '0',
        group   => '0',
        mode    => '0777',
        require => File['/etc/apache2/mods-available/passenger.conf'],
        notify  => Service['httpd'],
      }
    }
    'redhat': {
      package { 'libcurl-devel':
        ensure => present,
        before => Exec['compile-passenger'],
      }

      file { '/etc/httpd/conf.d/passenger.conf':
        ensure  => present,
        content => template('passenger/passenger-conf.erb'),
        owner   => '0',
        group   => '0',
        mode    => '0644',
      }
    }
    default:{
      fail("Operating system ${::operatingsystem} is not supported with the Passenger module")
    }
  }

  package {'passenger':
    name     => $passenger_package,
    ensure   => $passenger_version,
    provider => $passenger_provider,
  }

  exec {'compile-passenger':
    path      => [ $gem_binary_path, '/usr/bin', '/bin', '/usr/local/bin' ],
    command   => 'passenger-install-apache2-module -a',
    logoutput => on_failure,
    creates   => $mod_passenger_location,
    require   => Package['passenger'],
  }
}