Puppet Class: holland::install

Defined in:
manifests/install.pp

Summary

Basic install of Holland resources

Overview

Examples:

include holland::install

Parameters:

  • ensure (Enum['absent', 'present']) (defaults to: $::holland::ensure) 


7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
# File 'manifests/install.pp', line 7

class holland::install (
  Enum['absent', 'present'] $ensure = $::holland::ensure,
){
  # The base Holland package
  package { 'holland':
    ensure => $ensure,
  }

  $ensure_dir = $ensure ? {
    'present' => 'directory',
    default   => $ensure,
  }

  $ensure_file = $ensure ? {
    'present' => 'file',
    default   => $ensure,
  }

  # Make sure the configuration directories have the correct permissions.
  # Slightly more secure than the package defaults
  file { [
    '/etc/holland',
    '/etc/holland/backupsets',
    '/etc/holland/providers'
  ]:
    ensure  => $ensure_dir,
    owner   => 'root',
    group   => 'root',
    mode    => '0750',
    require => Package['holland'],
  }

  # Make sure `holland.conf` has the correct permissions
  file { '/etc/holland/holland.conf':
    ensure  => $ensure_file,
    owner   => 'root',
    group   => 'root',
    mode    => '0640',
    require => Package['holland'],
  }

}