Puppet Class: jenkins::slave

Inherits:
jenkins::params
Defined in:
manifests/slave.pp

Overview

Examples

class { 'jenkins::slave':
  masterurl => 'http://jenkins-master1.example.com:8080',
  ui_user => 'adminuser',
  ui_pass => 'adminpass',
}

Authors

Matthew Barr <mbarr@mbarr.net>

Copyright 2013 Matthew Barr , but can be used for anything by anyone..

Parameters:

  • slave_name (Any) (defaults to: undef)
  • description (Any) (defaults to: undef)
  • masterurl (Any) (defaults to: undef)
  • autodiscoveryaddress (Any) (defaults to: undef)
  • ui_user (Any) (defaults to: undef)
  • ui_pass (Any) (defaults to: undef)
  • version (Any) (defaults to: $jenkins::params::swarm_version)
  • executors (Any) (defaults to: 2)
  • manage_slave_user (Any) (defaults to: true)
  • slave_user (Any) (defaults to: 'jenkins-slave')
  • slave_uid (Any) (defaults to: undef)
  • slave_home (Any) (defaults to: '/home/jenkins-slave')
  • slave_mode (Any) (defaults to: 'normal')
  • disable_ssl_verification (Any) (defaults to: false)
  • labels (Any) (defaults to: undef)
  • tool_locations (Any) (defaults to: undef)
  • install_java (Any) (defaults to: $jenkins::params::install_java)
  • ensure (Any) (defaults to: 'running')
  • enable (Any) (defaults to: true) 


76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
 
# File 'manifests/slave.pp', line 76

class jenkins::slave (
  $slave_name               = undef,
  $description              = undef,
  $masterurl                = undef,
  $autodiscoveryaddress      = undef,
  $ui_user                  = undef,
  $ui_pass                  = undef,
  $version                  = $jenkins::params::swarm_version,
  $executors                = 2,
  $manage_slave_user        = true,
  $slave_user               = 'jenkins-slave',
  $slave_uid                = undef,
  $slave_home               = '/home/jenkins-slave',
  $slave_mode               = 'normal',
  $disable_ssl_verification = false,
  $labels                   = undef,
  $tool_locations           = undef,
  $install_java             = $jenkins::params::install_java,
  $ensure                   = 'running',
  $enable                   = true
) inherits jenkins::params {

  $client_jar = "swarm-client-${version}-jar-with-dependencies.jar"
  $client_url = "http://maven.jenkins-ci.org/content/repositories/releases/org/jenkins-ci/plugins/swarm-client/${version}/"

  if $install_java and ($::osfamily != 'Darwin') {
    # Currently the puppetlabs/java module doesn't support installing Java on
    # Darwin
    class { 'java':
      distribution => 'jdk',
    }
  }

  # customizations based on the OS family
  case $::osfamily {
    'Debian': {
      $defaults_location = '/etc/default'

      package { 'daemon':
        ensure => present,
        before => Service['jenkins-slave'],
      }
    }
    'Darwin': {
      $defaults_location = $slave_home
    }
    default: {
      $defaults_location = '/etc/sysconfig'
    }
  }

  case $::kernel {
    'Linux': {
      $fetch_command  = "wget -O ${slave_home}/${client_jar} ${client_url}/${client_jar}"
      $service_name   = 'jenkins-slave'
      $defaults_user  = 'root'
      $defaults_group = 'root'
      $manage_user_home = true

      file { '/etc/init.d/jenkins-slave':
        ensure => 'file',
        mode   => '0755',
        owner  => 'root',
        group  => 'root',
        source => "puppet:///modules/${module_name}/jenkins-slave.${::osfamily}",
        notify => Service['jenkins-slave'],
      }
    }
    'Darwin': {
      $fetch_command    = "curl -O ${client_url}/${client_jar}"
      $service_name     = 'org.jenkins-ci.slave.jnlp'
      $defaults_user    = 'jenkins'
      $defaults_group   = 'wheel'
      $manage_user_home = false

      file { "${slave_home}/start-slave.sh":
        ensure  => 'file',
        content => template("${module_name}/start-slave.sh.erb"),
        mode    => '0755',
        owner   => 'root',
        group   => 'wheel',
      }

      file { '/Library/LaunchDaemons/org.jenkins-ci.slave.jnlp.plist':
        ensure  => 'file',
        content => template("${module_name}/org.jenkins-ci.slave.jnlp.plist.erb"),
        mode    => '0644',
        owner   => 'root',
        group   => 'wheel',
      }

      file { '/var/log/jenkins':
        ensure => 'directory',
        owner  => $slave_user,
      }

      if $manage_slave_user {
        # osx doesn't have managehome support, so create directory
        file { $slave_home:
          ensure  => directory,
          mode    => '0755',
          owner   => $slave_user,
          require => User['jenkins-slave_user'],
        }
      }

      File['/var/log/jenkins'] ->
        File['/Library/LaunchDaemons/org.jenkins-ci.slave.jnlp.plist'] ->
          Service['jenkins-slave']
    }
    default: { }
  }

  #a Add jenkins slave user if necessary.
  if $manage_slave_user {
    user { 'jenkins-slave_user':
      ensure     => present,
      name       => $slave_user,
      comment    => 'Jenkins Slave user',
      home       => $slave_home,
      managehome => $manage_user_home,
      uid        => $slave_uid,
    }
  }

  file { "${defaults_location}/jenkins-slave":
    ensure  => 'file',
    mode    => '0600',
    owner   => $defaults_user,
    group   => $defaults_group,
    content => template("${module_name}/jenkins-slave-defaults.erb"),
    notify  => Service['jenkins-slave'],
  }

  exec { 'get_swarm_client':
    command => $fetch_command,
    path    => '/usr/bin:/usr/sbin:/bin:/usr/local/bin',
    user    => $slave_user,
    creates => "${slave_home}/${client_jar}",
    cwd     => $slave_home,
    #refreshonly  => true,
  ## needs to be fixed if you create another version..
  }

  service { 'jenkins-slave':
    ensure     => $ensure,
    name       => $service_name,
    enable     => $enable,
    hasstatus  => true,
    hasrestart => true,
  }

  Exec['get_swarm_client']
  -> Service['jenkins-slave']

  if $install_java and ($::osfamily != 'Darwin') {
    Class['java'] ->
    Service['jenkins-slave']
  }
}