236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
|
# File 'manifests/init.pp', line 236
class adguard
(
Stdlib::IP::Address::V4::Nosubnet $webui_interface,
Stdlib::Port $webui_port,
Tuple[Struct[
username => String,
password => String
],1,default] $users,
Optional[Stdlib::HTTPUrl] $http_proxy,
Integer $rlimit_nofile,
Boolean $debug_pprof,
Integer $web_session_ttl,
Stdlib::IP::Address::V4::Nosubnet $dns_interface,
Stdlib::Port $dns_port,
Integer $statistics_interval,
Boolean $querylog_enabled,
Boolean $querylog_file_enabled,
Integer $querylog_interval,
Integer $querylog_size_memory,
Boolean $anonymize_client_ip,
Boolean $protection_enabled,
Enum['default','null_ip','custom_ip'] $blocking_mode,
Optional[Stdlib::IP::Address::V4::Nosubnet] $blocking_ipv4,
Optional[Stdlib::IP::Address::V6] $blocking_ipv6,
Integer $blocked_response_ttl,
Variant[Stdlib::Fqdn,Stdlib::IP::Address] $parental_block_host,
Variant[Stdlib::Fqdn,Stdlib::IP::Address] $safebrowsing_block_host,
Integer $ratelimit,
Optional[Tuple[Stdlib::IP::Address,1,default]] $ratelimit_whitelist,
Boolean $refuse_any,
Tuple[Variant[Stdlib::IP::Address,Stdlib::HTTPUrl],1,4] $upstream_dns,
Optional[Stdlib::Unixpath] $upstream_dns_file,
Tuple[Stdlib::IP::Address,1,default] $bootstrap_dns,
Boolean $all_servers,
Boolean $fastest_addr,
Optional[Tuple[Stdlib::IP::Address,1,default]] $allowed_clients,
Optional[Tuple[Stdlib::IP::Address,1,default]] $disallowed_clients,
Array $blocked_hosts,
Integer $dns_cache_size,
Integer[default,3600] $dns_cache_ttl_min,
Integer[default,3600] $dns_cache_ttl_max,
Optional[Tuple[Stdlib::Fqdn,Stdlib::IP::Address::V4::Nosubnet,1,default]] $bogus_nxdomain,
Boolean $aaaa_disabled,
Boolean $enable_dnssec,
Boolean $edns_client_subnet,
Integer $max_goroutines,
Boolean $filtering_enabled,
Integer $filters_update_interval,
Boolean $parental_enabled,
Boolean $safesearch_enabled,
Boolean $safebrowsing_enabled,
Integer $safebrowsing_cache_size,
Integer $safesearch_cache_size,
Integer $parental_cache_size,
Integer $cache_time,
Optional[Struct[
domain => String,
answer => String,
]] $rewrites,
Optional[Tuple[Adguard::Blocked_service,1,default]] $blocked_services,
Tuple[Struct[
name => String,
enabled => Boolean,
url => Stdlib::HTTPUrl,
],1,default] $filters,
Optional[Tuple[Struct[
name => String,
enabled => Boolean,
url => Stdlib::HTTPUrl,
],1,default]] $whitelist_filters,
Optional[Array] $user_rules,
Optional[Tuple[Struct[
name => String,
tags => Optional[Array],
ids => Array,
use_global_settings => Boolean,
filtering_enabled => Optional[Boolean],
parental_enabled => Optional[Boolean],
safesearch_enabled => Optional[Boolean],
use_global_blocked_services => Boolean,
blocked_services => Optional[Array],
upstreams => Optional[Array]
],1,default]] $clients,
Boolean $log_compress,
Boolean $log_localtime,
Integer $log_max_backups,
Integer $log_max_size,
Integer $log_max_age,
Boolean $verbose_logging,
Variant[Stdlib::Unixpath,Enum['syslog'],Undef] $log_file,
Stdlib::Unixpath $adguard_path,
Boolean $manage_config,
Pattern[/(.*\/)(.*)(AdGuardHome.yaml$)/] $configuration_file,
String $service_name,
String $version,
)
{
if ($blocking_mode == 'custom_ip')
{
if (!$blocking_ipv4 or !$blocking_ipv6)
{
fail('blocking_ipv4 and/or blocking_ipv6 must be declared when blocking_mode is set to custom_ip')
}
}
if ($clients)
{
# Sanity check the client data
$clients.each | $client | {
# When using global settings we can't specify individual settings
if ($client['use_global_settings'] == true)
{
if ($client['filtering_enabled'] or $client['parental_enabled'] or $client['safesearch_enabled'] or $client['safebrowsing_enabled'])
{
fail('cannot set individual client settings when use_global_settings is true')
}
}
if ($client['use_global_blocked_services'] == true)
{
if ($client['blocked_services'])
{
fail ('cannot declare blocked_services when use_global_blocked_services is true')
}
}
}
}
# Puppet has excellent facts, make use of them
case $::architecture
{
/(amd64|x64)/:
{
$cpu_arch = 'amd64'
}
/(i386|i486|i686|i786|x86)/:
{
$cpu_arch = '386'
}
default:
{
fail('unsupported cpu architecture')
}
}
# Annoyingly the AdGuard archives container a folder instead of being directly in the root :(
# Get the parent path unless we're already installing to the root of somewhere
if ($adguard_path =~ /(.*\/)(.*)AdGuardHome$/)
{
$extract_path = $1
}
else
{
$extract_path = $adguard_path
}
$extension = '.tar.gz' # right now we only support tar.gz, but if we add support for Windows we'll need to support .zip as well
$kernel = downcase($::kernel)
# Ensure the path exists with the relevant permissions
file { $adguard_path:
ensure => directory,
owner => 'root',
group => 'root',
mode => '0755',
}
# Copy the configuration file
file { $configuration_file:
ensure => present,
owner => 'root',
group => 'root',
mode => '0644', # Stop fighting with AdGuard
replace => $manage_config,
backup => '.puppet',
content => template('adguard/AdGuardHome.yaml.erb'),
require => File[$adguard_path],
notify => Service[$service_name],
}
# Download the release from GitHub and extract it
githubreleases_download { "${adguard_path}/adguard${extension}":
author => 'AdguardTeam',
repository => 'AdGuardHome',
asset => true,
asset_filepattern => "^AdGuardHome_${kernel}_${cpu_arch}${extension}",
release => $version,
require => File[$adguard_path],
}
archive { "${adguard_path}/adguard${extension}":
extract => true,
extract_path => $extract_path,
creates => "${adguard_path}/AdGuardHome",
require => Githubreleases_download["${adguard_path}/adguard${extension}"],
}
exec { 'install_adguard':
command => "${adguard_path}/AdGuardHome -s install -c ${configuration_file}",
creates => '/etc/systemd/system/AdGuardHome.service',
require => Archive["${adguard_path}/adguard${extension}"],
}
service { $service_name:
ensure => 'running',
subscribe => File[$configuration_file],
require => Exec['install_adguard']
}
# If we're on a systemd and we're using port 53 we'll get an issue in starting up due to resolved, so we'll need to sort that out
if (($::systemd == true or $::os['family'] =~ /[dD]ebian/) and $dns_port == 53)
{
notice('disabling resolved DNSStubListener')
ini_setting {'adguard_disable_DNSStubListener':
ensure => present,
path => '/etc/systemd/resolved.conf',
setting => 'DNSStubListener',
key_val_separator => '=',
value => 'no',
section => 'Resolve',
section_prefix => '[',
section_suffix => ']',
notify => Service['systemd_resolved_adguard'],
# Ordering is important here - essentially we want to ensure we've downloaded the AdGuard package before we kill name resolution
# but we need to make the change before starting the AdGuard service.
before => Service[$service_name],
require => Githubreleases_download["${adguard_path}/adguard${extension}"],
}
service {'systemd_resolved_adguard':
ensure => 'running',
name => 'systemd-resolved',
subscribe => Ini_setting['adguard_disable_DNSStubListener']
}
}
}
|