Puppet Class: auditd
- Defined in:
- manifests/init.pp
Summary
Configure the audit daemon for use with a specified audit profile.Overview
Any variable that is not described here can be found in auditd.conf(5) and auditctl(8).
206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 |
# File 'manifests/init.pp', line 206
class auditd (
# Control Parameters
Boolean $enable = true,
Optional[Variant[Enum['simp'],Boolean]] $default_audit_profile = undef,
Array[Auditd::AuditProfile] $default_audit_profiles = [ 'simp' ],
Boolean $audit_auditd_config = true,
String $lname = $facts['networking']['fqdn'],
# Rule Tweaks
Boolean $ignore_anonymous = true,
Boolean $ignore_crond = true,
Boolean $ignore_time_daemons = true,
Boolean $ignore_crypto_key_user = true,
Boolean $ignore_errors = true,
Boolean $ignore_failures = true,
Boolean $ignore_system_services = true,
# Configuration Parameters
String[1] $action_mail_acct = 'root',
Variant[Integer[0],Pattern['^\d+%$']] $admin_space_left = 50,
Auditd::SpaceLeftAction $admin_space_left_action = 'rotate',
Boolean $at_boot = true,
Integer[0] $buffer_size = 16384,
Optional[Integer[1,600000]] $backlog_wait_time = undef,
Auditd::DiskErrorAction $disk_error_action = 'syslog',
Auditd::DiskFullAction $disk_full_action = 'rotate',
Enum['lossy','lossless'] $disp_qos = 'lossy',
Stdlib::Absolutepath $dispatcher = '/sbin/audispd',
Integer[0] $failure_mode = 1,
Auditd::Flush $flush = 'incremental',
Integer[0] $freq = 20,
Boolean $immutable = false,
Optional[Boolean] $local_events = undef,
Stdlib::Absolutepath $log_file = '/var/log/audit/audit.log',
Auditd::LogFormat $log_format = 'raw',
String $log_group = 'root',
Boolean $loginuid_immutable = true,
Integer[0] $max_log_file = 24,
Auditd::MaxLogFileAction $max_log_file_action = 'rotate',
Optional[Integer[1]] $max_restarts = undef, #data in module, #auditd version 3.0 and later
Auditd::NameFormat $name_format = 'user',
Integer[0] $num_logs = 5,
Optional[Auditd::Overflowaction] $overflow_action = undef, # data in module
String[1] $package_name = 'audit',
Simplib::PackageEnsure $package_ensure = simplib::lookup('simp_options::package_ensure', { 'default_value' => 'installed' }),
Stdlib::Absolutepath $plugin_dir, # data in module
Integer[0] $priority_boost = 3,
Integer[0] $q_depth = 400,
Integer[0] $rate = 0,
Auditd::RootAuditLevel $root_audit_level = 'basic',
String[1] $service_name = 'auditd',
Variant[Integer[0],Pattern['^\d+%$']] $space_left = auditd::calculate_space_left($admin_space_left),
Auditd::SpaceLeftAction $space_left_action = 'syslog',
Boolean $syslog = simplib::lookup('simp_options::syslog', {'default_value' => false }), # CCE-26933-2
Optional[Array[Pattern['^.*_t$']]] $target_selinux_types = undef,
Integer[0] $uid_min = Integer(pick(fact('uid_min'), 1000)),
Optional[Boolean] $verify_email = undef,
Boolean $write_logs = $log_format ? { /^(?i:nolog)$/ => false, default => true },
Boolean $purge_auditd_rules = true,
) {
include 'auditd::service'
if $enable {
simplib::assert_metadata($module_name)
auditd::validate_init_params()
if $facts['auditd_version'] and ( versioncmp($facts['auditd_version'], '2.6.0') < 0 ) {
if ( versioncmp($facts['auditd_version'], '2.5.2') < 0 ) {
unless $write_logs {
$_log_format = 'NOLOG'
}
}
else {
# Versions > 2.5.2 do not handle NOLOG
if $log_format == 'NOLOG' {
$_log_format = 'raw'
}
$_write_logs = $write_logs
}
unless defined('$_log_format') {
# ENRICHED was not added until 2.6.0
if $log_format == 'ENRICHED' {
$_log_format = 'raw'
}
else {
$_log_format = $log_format
}
}
}
else {
# Versions >= 2.6.0 do not support NOLOG
if $log_format == 'NOLOG' {
$_log_format = 'raw'
}
else {
$_log_format = $log_format
}
$_write_logs = $write_logs
}
# This is done here so that the kernel option can be properly removed if
# auditing is to be disabled on the system.
if $at_boot {
$_grub_enable = true
}
else {
$_grub_enable = false
}
include 'auditd::install'
include 'auditd::config'
Class['auditd::install']
-> Class['auditd::config']
~> Class['auditd::service']
-> Class['auditd']
if fact('grub_version') {
Class['auditd::install'] -> Class['::auditd::config::grub']
}
}
else {
$_grub_enable = false
}
# This is done deliberately so that you cannot conflict a direct call to
# auditd::config::grub with an include somewhere else. auditd::config::grub
# would normally be a private class but may be used independently if
# necessary.
if fact('grub_version') {
class { 'auditd::config::grub': enable => $_grub_enable }
}
}
|