Puppet Class: freeradius::v3::sites::ldap

Inherits:
freeradius
Defined in:
manifests/v3/sites/ldap.pp

Summary

This will create a site that will authenticate using LDAP and listen

Overview

on the interface defined by ‘listen_ip`

The Default is to listen on all interfaces.

Parameters:

  • site_name (String) (defaults to: 'default') —

    The name of the site

  • enable (Boolean) (defaults to: true) —

    Whether to enable the site or not

  • confdir (Stdlib::Absolutepath) (defaults to: $freeradius::confdir) —

    Configuration directory for freeradius

  • include_listener (Boolean) (defaults to: true) —

    If set to true then ‘listen’ sections will be set up for the site. Otherwise the listen_ip will be ignored and the user will be required to set up a listener using the listener.pp module.

  • group (String) (defaults to: $freeradius::group) —

    Group radiusd runs under.

  • listen_ip (Simplib::Host) (defaults to: 'ALL') —

    The ip addresses to listen on. See setting ipaddr in sites-enabled/default.

  • max_connections (Integer) (defaults to: 16)
  • lifetime (Integer) (defaults to: 0)
  • idle_timeout (Integer) (defaults to: 30)

See Also:

  • for more information on sites


32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
 
# File 'manifests/v3/sites/ldap.pp', line 32

class freeradius::v3::sites::ldap (
  String               $site_name        = 'default',
  Boolean              $enable           = true,
  Boolean              $include_listener = true,
  Simplib::Host        $listen_ip        = 'ALL',
  Stdlib::Absolutepath $confdir          = $freeradius::confdir,
  String               $group            = $freeradius::group,
  Integer              $max_connections  = 16,
  Integer              $lifetime         = 0,
  Integer              $idle_timeout     = 30
) inherits freeradius {

  $_target = "${confdir}/sites-available/simp-ldap-default"

  concat { 'site_simp_ldap_default':
    ensure => present,
    path   => $_target,
    owner  => 'root',
    group  => $group,
    mode   => '0640',
    notify => Service['radiusd'],
    order  => 'numeric'
  }

  concat::fragment { 'site_ldap_header':
    target  => $_target,
    content => epp('freeradius/3/sites/ldap_header.epp'),
    order   => 0
  }

  if $include_listener {
    freeradius::v3::listen { 'site_ldap_auth':
      target          => $_target,
      order           => 10,
      listen_type     => 'auth',
      ipaddr          => $listen_ip,
      port            => 0,
      max_connections => $max_connections,
      idle_timeout    => $idle_timeout,
      lifetime        => $lifetime
    }

    freeradius::v3::listen { 'site_ldap_acct':
      target      => $_target,
      order       => 11,
      listen_type => 'acct',
      ipaddr      => $listen_ip,
      port        => 0
    }
  }

  concat::fragment { 'site_ldap_footer':
    target  => $_target,
    order   => 100,
    content => epp('freeradius/3/sites/ldap_footer.epp')
  }

  if $enable {
    file {  "${confdir}/sites-enabled/${site_name}":
      ensure => 'link',
      target => $_target,
      owner  => 'root',
      group  => $group,
      notify => Service['radiusd'],
      mode   => '0640',
    }
  }
}