Puppet Class: hirs_provisioner

Defined in:
manifests/init.pp

Summary

Installs HIRS_Provisioner RPM and configures and registers with HIRS ACA

Overview

Parameters:

  • enable (Boolean) (defaults to: true) —

    This module will install and mangage HIRS unless ‘false`

  • package_ensure (String[1]) (defaults to: simplib::lookup('simp_options::package_ensure', {'default_value' => 'installed'})) —

    The default ensure parameter for packages.

  • tpm_1_2_packages (Hash[String[1], Optional[Hash]]) (defaults to: { 'HIRS_Provisioner_TPM_1_2' => {} }) —

    A hash of packages needed for HIRS with TPM 1.2.

    • NOTE: Setting this will override the default package list

    • The ensure value can be set in the hash of each package, like the example below:

    Example: Override packages “‘ { ’HIRS_Provisioner’ => { ‘ensure’ => ‘3.14.3’ } } “‘

  • tpm_2_0_packages (Hash[String[1], Optional[Hash]]) (defaults to: { 'HIRS_Provisioner_TPM_2_0' => {} }) —

    A hash of packages needed for HIRS with TPM 2.0.

Author:



26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
# File 'manifests/init.pp', line 26

class hirs_provisioner (
  Boolean                         $enable           = true,
  String[1]                       $package_ensure   = simplib::lookup('simp_options::package_ensure', {'default_value' => 'installed'}),
  Hash[String[1], Optional[Hash]] $tpm_1_2_packages = { 'HIRS_Provisioner_TPM_1_2' => {} },
  Hash[String[1], Optional[Hash]] $tpm_2_0_packages = { 'HIRS_Provisioner_TPM_2_0' => {} }
) {

  simplib::assert_metadata($module_name)

  if $facts['hirs_tpm_1_2_enabled'] {
    $tpm_version = '1.2'
    $_packages = $tpm_1_2_packages
  } elsif $facts['hirs_tpm_2_0_enabled'] {
    $tpm_version = '2.0'
    $_packages = $tpm_2_0_packages
  }

  if $enable {
    if !defined('$_packages') {
      notice('No TPM detected on $fqdn; skipping HIRS Provisioner installation')
    } else {
      $_tpm_enabled = true
      include 'hirs_provisioner::install'
      include 'hirs_provisioner::config'

      Class[ 'hirs_provisioner::install' ]
      -> Class[ 'hirs_provisioner::config' ]
    }
  }
}