Puppet Class: pupmod
- Inherited by:
-
pupmod::master
pupmod::master::sysconfig
- Defined in:
- manifests/init.pp
Overview
A class for managing Puppet configurations.
This is mainly a stub class for hooking other classes along the way with a small bit of logic to flex the system toward being a Puppet master or client. It manages Puppet and Facter configurations.
All Puppet configuration parameters are, by default, written to the
- main
-
config block of the Puppet configuration file. Selective options
may be written to their respective components as necessary for deconfliction.
176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 |
# File 'manifests/init.pp', line 176
class pupmod (
Variant[Simplib::Host,Enum['$server']] $ca_server = simplib::lookup('simp_options::puppet::ca', { 'default_value' => '$server' }),
Simplib::Port $ca_port = simplib::lookup('simp_options::puppet::ca_port', { 'default_value' => 8141 }),
Variant[Simplib::Host, Array[Simplib::Host]] $puppet_server = simplib::lookup('simp_options::puppet::server', { 'default_value' => "puppet.${facts['networking']['domain']}" }),
Simplib::ServerDistribution $server_distribution = pupmod::server_distribution(false), # Can't self-reference in this lookup
Simplib::Host $certname = ($trusted['authenticatedx'] ? {
'remote' => $trusted['certname'],
default => pick($facts['clientcert'], $facts['networking']['fqdn']),
}),
String[0] $classfile = '$vardir/classes.txt',
Stdlib::AbsolutePath $confdir,
Boolean $daemonize = false,
Enum['md5','sha256'] $digest_algorithm = 'sha256',
Boolean $enable_puppet_master = false,
Stdlib::AbsolutePath $environmentpath,
Boolean $listen = false,
Stdlib::AbsolutePath $logdir,
Boolean $purge_logs = true,
Pattern['\d+(h|m|w)'] $purge_logs_duration = '4w',
Array[Stdlib::AbsolutePath] $purge_log_dirs = ['/puppet*'],
Simplib::Port $masterport = 8140,
Boolean $report = false,
Stdlib::AbsolutePath $rundir,
Integer[0] $runinterval = 1800,
Boolean $splay = false,
Optional[Integer[1]] $splaylimit = undef,
Simplib::Host $srv_domain = $facts['networking']['domain'],
Stdlib::AbsolutePath $ssldir,
Simplib::Syslog::Facility $syslogfacility = 'local6',
Boolean $use_srv_records = false,
Stdlib::AbsolutePath $vardir,
Boolean $haveged = simplib::lookup('simp_options::haveged', { 'default_value' => false }),
Boolean $fips = simplib::lookup('simp_options::fips', { 'default_value' => false }),
Boolean $firewall = simplib::lookup('simp_options::firewall', { 'default_value' => false }),
Hash $pe_classlist = {},
String[1] $package_ensure = simplib::lookup('simp_options::package_ensure' , { 'default_value' => 'installed'}),
Variant[Boolean, Enum['no_clean']] $set_environment = false,
Boolean $manage_facter_conf = false,
Stdlib::Absolutepath $facter_conf_dir = '/etc/puppetlabs/facter',
Hash $facter_options, # module data
Boolean $mock = false
) {
unless $mock {
simplib::assert_metadata($module_name)
# This regex matches absolute paths or paths that begin with an existing
# puppet configuration variable, like $vardir
assert_type(Pattern['^(\$(?!/)|/).+'], $classfile)
if $haveged {
include '::haveged'
}
if $enable_puppet_master {
include 'pupmod::master'
}
package { 'puppet-agent': ensure => $package_ensure }
if $daemonize {
$_puppet_service_ensure = 'running'
}
else {
$_puppet_service_ensure = 'stopped'
}
include 'pupmod::agent::cron'
service { 'puppet':
ensure => $_puppet_service_ensure,
enable => $daemonize,
hasrestart => true,
hasstatus => true,
subscribe => File["${confdir}/puppet.conf"]
}
pupmod::conf { 'agent_daemonize':
section => 'agent',
confdir => $confdir,
setting => 'daemonize',
value => $daemonize
}
# This takes some explaining. You may be asking yourself: Dear god? why?
#
# The short answer is, to make the UX for PE better, we need to make no
# assumptions about the amount of configuration the user has done before
# trying to lay SIMP on top of PE.
#
# Therefore, we have to inspect the catalog to see which PE
# classes are included, and tailor our configuration
# accordingly.
#
# To do this we have to use defined(). But this has an inherent
# race condition if you use it in a normal class, as if this class
# is evaluated before the class you are checking, you
# will get an erroneous false result.
#
# The workaround is to take advantage of the fact that the puppet catalog
# compiler takes multiple passes, a first pass for most classes to be
# evaluated, and a second pass for resource collection statements. Basically
# by creating a virtual defined type and realizing it immediately, we
# 'throw' any puppet code in the defined type into the next pass of the
# compiler.
#
# Disgusting? yes. Necessary? unfortunately. This will have to be
# re-evaluated for every major PE release.
@pupmod::pass_two { 'main':
server_distribution => $server_distribution,
confdir => $confdir,
firewall => $firewall,
pe_classlist => $pe_classlist,
pupmod_server => $puppet_server,
pupmod_ca_server => $ca_server,
pupmod_masterport => $masterport,
pupmod_ca_port => $ca_port,
pupmod_report => $report,
}
Pupmod::Pass_two <| |>
if !empty($splaylimit) {
pupmod::conf { 'splaylimit':
confdir => $confdir,
setting => 'splaylimit',
value => $splaylimit
}
}
if $set_environment {
unless ($set_environment == 'no_clean') {
pupmod::conf { 'remove environment from main':
ensure => 'absent',
section => 'main',
confdir => $confdir,
setting => 'environment',
value => null
}
}
unless simplib::in_bolt() {
pupmod::conf { 'environment':
confdir => $confdir,
setting => 'environment',
value => $environment
}
}
}
pupmod::conf {
default: confdir => $confdir;
'splay':
setting => 'splay',
value => $splay;
'syslogfacility':
setting => 'syslogfacility',
value => $syslogfacility;
'srv_domain':
setting => 'srv_domain',
value => $srv_domain;
'certname':
setting => 'certname',
value => $certname;
'vardir':
setting => 'vardir',
value => $vardir;
'classfile':
setting => 'classfile',
value => $classfile;
'confdir':
setting => 'confdir',
value => $confdir,;
'logdir':
setting => 'logdir',
value => $logdir;
'rundir':
setting => 'rundir',
value => $rundir;
'runinterval':
setting => 'runinterval',
value => $runinterval;
'ssldir':
setting => 'ssldir',
value => $ssldir;
'stringify_facts':
setting => 'stringify_facts',
value => false;
'digest_algorithm':
setting => 'digest_algorithm',
value => $digest_algorithm;
}
# This is to allow the hosts to boot faster. It should probably be
# re-worked.
file { '/etc/sysconfig/puppet':
ensure => 'file',
owner => 'root',
group => 'root',
mode => '0644',
content => "PUPPET_EXTRA_OPTS='--daemonize'\n"
}
$puppet_agent_sebool = 'puppetagent_manage_all_files'
if $facts['os']['selinux']['enabled'] and $facts['os']['selinux']['current_mode'] and ($facts['os']['selinux']['current_mode'] != 'disabled') {
selboolean { $puppet_agent_sebool :
persistent => true,
value => 'on'
}
}
if $manage_facter_conf {
include 'pupmod::facter::conf'
}
if $purge_logs {
unless empty($purge_log_dirs) {
$_purge_logdir = dirname($logdir)
if empty($_purge_logdir) or ($_purge_logdir == '/') {
fail("Refusing to purge top-level directories. Please ensure that ${module_name}::logdir is set to something sensible.")
}
$_purge_logs_content = $purge_log_dirs.map |$x| { "e ${_purge_logdir}${x} - - - ${purge_logs_duration}" }
systemd::tmpfile { 'puppet_purge_puppet_service_logs.conf':
content => join($_purge_logs_content, "\n")
}
}
}
else {
systemd::tmpfile { 'puppet_purge_puppet_service_logs': ensure => 'absent' }
}
}
}
|