Puppet Class: ceilometer::alarm::notifier

Defined in:
manifests/alarm/notifier.pp

Overview

Installs the ceilometer alarm notifier service

Params

[*enabled*]
  (optional) Should the service be enabled.
  Defaults to true.

[*manage_service*]
  (optional) Whether the service should be managed by Puppet.
  Defaults to true.

[*notifier_rpc_topic*]
  (optional) Define on which topic the notifier will have access.
  Defaults to undef.

[*rest_notifier_certificate_key*]
  (optional) Define the certificate key for the rest service.
  Defaults to undef.

[*rest_notifier_certificate_file*]
  (optional) Define the certificate file for the rest service.
  Defaults to undef.

[*rest_notifier_ssl_verify*]
  (optional) Should the ssl verify parameter be enabled.
  Defaults to true.

Parameters:

  • manage_service (Any) (defaults to: true)
  • enabled (Any) (defaults to: true)
  • notifier_rpc_topic (Any) (defaults to: undef)
  • rest_notifier_certificate_key (Any) (defaults to: undef)
  • rest_notifier_certificate_file (Any) (defaults to: undef)
  • rest_notifier_ssl_verify (Any) (defaults to: true) 


28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
 
# File 'manifests/alarm/notifier.pp', line 28

class ceilometer::alarm::notifier (
  $manage_service                 = true,
  $enabled                        = true,
  $notifier_rpc_topic             = undef,
  $rest_notifier_certificate_key  = undef,
  $rest_notifier_certificate_file = undef,
  $rest_notifier_ssl_verify       = true,
) {

  include ceilometer::params

  validate_bool($rest_notifier_ssl_verify)

  Ceilometer_config<||> ~> Service['ceilometer-alarm-notifier']

  Package[$::ceilometer::params::alarm_package_name] -> Service['ceilometer-alarm-notifier']
  Package[$::ceilometer::params::alarm_package_name] -> Package<| title == 'ceilometer-alarm' |>
  ensure_packages($::ceilometer::params::alarm_package_name)

  if $manage_service {
    if $enabled {
      $service_ensure = 'running'
    } else {
      $service_ensure = 'stopped'
    }
  }

  Package['ceilometer-common'] -> Service['ceilometer-alarm-notifier']

  service { 'ceilometer-alarm-notifier':
    ensure     => $service_ensure,
    name       => $::ceilometer::params::alarm_notifier_service_name,
    enable     => $enabled,
    hasstatus  => true,
    hasrestart => true
  }

  if $notifier_rpc_topic != undef {
    ceilometer_config {
      'alarm/notifier_rpc_topic' : value => $notifier_rpc_topic;
    }
  }
  if $rest_notifier_certificate_key  != undef {
    ceilometer_config {
      'alarm/rest_notifier_certificate_key' :value => $rest_notifier_certificate_key;
      'alarm/rest_notifier_ssl_verify'      :value => $rest_notifier_ssl_verify;
    }
  }
  if $rest_notifier_certificate_file != undef {
    ceilometer_config {
      'alarm/rest_notifier_certificate_file' :value => $rest_notifier_certificate_file;
    }
  }

}