Puppet Class: neutron::agents::vpnaas

Defined in:
manifests/agents/vpnaas.pp

Overview

Copyright © 2013 eNovance SAS <licensing@enovance.com>

Author: Emilien Macchi <emilien.macchi@enovance.com>

Licensed under the Apache License, Version 2.0 (the “License”); you may not use this file except in compliance with the License. You may obtain a copy of the License at

http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on an “AS IS” BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the specific language governing permissions and limitations under the License.

Class: neutron::agents:vpnaas

Setups Neutron VPN agent.

Parameters

package_ensure

(optional) Ensure state for package. Defaults to ‘present’.

enabled

(optional) Enable state for service. Defaults to ‘true’.

manage_service

(optional) Whether to start/stop the service Defaults to true

vpn_device_driver

(optional) Defaults to ‘neutron.services.vpn.device_drivers.ipsec.OpenSwanDriver’.

interface_driver

(optional) Defaults to ‘neutron.agent.linux.interface.OVSInterfaceDriver’.

*external_network_bridge

(optional) Defaults to undef

ipsec_status_check_interval

(optional) Status check interval. Defaults to ‘60’.

Parameters:

  • package_ensure (Any) (defaults to: present)
  • enabled (Any) (defaults to: true)
  • manage_service (Any) (defaults to: true)
  • vpn_device_driver (Any) (defaults to: 'neutron.services.vpn.device_drivers.ipsec.OpenSwanDriver')
  • interface_driver (Any) (defaults to: 'neutron.agent.linux.interface.OVSInterfaceDriver')
  • external_network_bridge (Any) (defaults to: undef)
  • ipsec_status_check_interval (Any) (defaults to: '60') 


46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
 
# File 'manifests/agents/vpnaas.pp', line 46

class neutron::agents::vpnaas (
  $package_ensure              = present,
  $enabled                     = true,
  $manage_service              = true,
  $vpn_device_driver           = 'neutron.services.vpn.device_drivers.ipsec.OpenSwanDriver',
  $interface_driver            = 'neutron.agent.linux.interface.OVSInterfaceDriver',
  $external_network_bridge     = undef,
  $ipsec_status_check_interval = '60'
) {

  include neutron::params

  Neutron_config<||>              ~> Service['neutron-vpnaas-service']
  Neutron_vpnaas_agent_config<||> ~> Service['neutron-vpnaas-service']

  case $vpn_device_driver {
    /\.OpenSwan/: {
      Package['openswan'] -> Package<| title == 'neutron-vpnaas-agent' |>
      package { 'openswan':
        ensure => present,
        name   => $::neutron::params::openswan_package,
      }
    }
    default: {
      fail("Unsupported vpn_device_driver ${vpn_device_driver}")
    }
  }

  # The VPNaaS agent loads both neutron.ini and its own file.
  # This only lists config specific to the agent.  neutron.ini supplies
  # the rest.
  neutron_vpnaas_agent_config {
    'vpnagent/vpn_device_driver':        value => $vpn_device_driver;
    'ipsec/ipsec_status_check_interval': value => $ipsec_status_check_interval;
    'DEFAULT/interface_driver':          value => $interface_driver;
  }

  if ($external_network_bridge) {
    neutron_vpnaas_agent_config {
      'DEFAULT/external_network_bridge': value => $external_network_bridge;
    }
  } else {
    neutron_vpnaas_agent_config {
      'DEFAULT/external_network_bridge': ensure => absent;
    }
  }

  if $::neutron::params::vpnaas_agent_package {
    Package['neutron']            -> Package['neutron-vpnaas-agent']
    Package['neutron-vpnaas-agent'] -> Neutron_vpnaas_agent_config<||>
    package { 'neutron-vpnaas-agent':
      ensure  => $package_ensure,
      name    => $::neutron::params::vpnaas_agent_package,
    }
  } else {
    Package['neutron'] -> Neutron_vpnaas_agent_config<||>
  }

  if $manage_service {
    if $enabled {
      $service_ensure = 'running'
    } else {
      $service_ensure = 'stopped'
    }
  }

  service { 'neutron-vpnaas-service':
    ensure  => $service_ensure,
    name    => $::neutron::params::vpnaas_agent_service,
    enable  => $enabled,
    require => Class['neutron'],
  }
}