Puppet Class: iop::service_remediations

Defined in:
manifests/service_remediations.pp

Overview

Class: iop::service_remediations

Install and configure the Remediations service

Parameters:

$image

The container image

$ensure

Ensure service is present or absent

$database_user

Username for the remediations database

$database_name

Name of the remediations database

$database_password

Password for the remediations database

$database_host

Host for the remediations database

$database_port

Port for the remediations database

Parameters:

  • image (String[1]) (defaults to: 'quay.io/iop/remediations:latest')
  • ensure (Enum['present', 'absent']) (defaults to: 'present')
  • database_name (String[1]) (defaults to: 'remediations_db')
  • database_user (String[1]) (defaults to: 'remediations_user')
  • database_password (String[1]) (defaults to: extlib::cache_data('iop_cache_data', 'remediations_db_password', extlib::random_password(32)))
  • database_host (String[1]) (defaults to: '/var/run/postgresql')
  • database_port (Stdlib::Port) (defaults to: 5432) 


21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
 
# File 'manifests/service_remediations.pp', line 21

class iop::service_remediations (
  String[1] $image = 'quay.io/iop/remediations:latest',
  Enum['present', 'absent'] $ensure = 'present',
  String[1] $database_name = 'remediations_db',
  String[1] $database_user = 'remediations_user',
  String[1] $database_password = extlib::cache_data('iop_cache_data', 'remediations_db_password', extlib::random_password(32)),
  String[1] $database_host = '/var/run/postgresql',
  Stdlib::Port $database_port = 5432,
) {
  include podman
  include iop::database
  include iop::core_kafka
  include iop::core_network
  include iop::core_host_inventory
  include iop::service_advisor

  $service_name = 'iop-service-remediations-api'
  $database_username_secret_name = "${service_name}-database-username"
  $database_password_secret_name = "${service_name}-database-password"
  $database_name_secret_name = "${service_name}-database-name"
  $database_host_secret_name = "${service_name}-database-host"
  $database_port_secret_name = "${service_name}-database-port"

  $socket_volume = $database_host ? {
    /^\/var\/run\/postgresql/ => ['/var/run/postgresql:/var/run/postgresql:rw'],
    default                   => [],
  }

  podman::secret { $database_username_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_user),
  }

  podman::secret { $database_password_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_password),
  }

  podman::secret { $database_name_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_name),
  }

  podman::secret { $database_host_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_host),
  }

  podman::secret { $database_port_secret_name:
    ensure => $ensure,
    secret => Sensitive(String($database_port)),
  }

  # Prevents errors if run from /root etc.
  Postgresql_psql {
    cwd => '/',
  }

  include postgresql::client, postgresql::server

  postgresql::server::db { $database_name:
    user     => $database_user,
    password => postgresql::postgresql_password($database_user, $database_password),
    owner    => $database_user,
    encoding => 'utf8',
    locale   => 'en_US.utf8',
  }

  podman::quadlet { $service_name:
    ensure       => $ensure,
    quadlet_type => 'container',
    user         => 'root',
    require      => [
      Podman::Network['iop-core-network'],
      Postgresql::Server::Db[$database_name],
      Podman::Secret[$database_username_secret_name],
      Podman::Secret[$database_password_secret_name],
      Podman::Secret[$database_name_secret_name],
      Podman::Secret[$database_host_secret_name],
      Podman::Secret[$database_port_secret_name],
    ],
    settings     => {
      'Unit'      => {
        'Description' => 'Remediations API',
        'Wants'       => ['iop-core-host-inventory-api.service', 'iop-service-advisor-backend-api.service'],
        'After'       => ['iop-core-host-inventory-api.service', 'iop-service-advisor-backend-api.service'],
      },
      'Container' => {
        'Image'         => $image,
        'ContainerName' => 'iop-service-remediations-api',
        'Network'       => 'iop-core-network',
        'Exec'          => 'sh -c "npm run db:migrate && exec node --max-http-header-size=16384 src/app.js"',
        'Volume'        => $socket_volume,
        'Environment'   => [
          'REDIS_ENABLED=false',
          'RBAC_ENFORCE=false',
          'CONTENT_SERVER_HOST=http://iop-service-advisor-backend-api:8000',
          'ADVISOR_HOST=http://iop-service-advisor-backend-api:8000',
          'INVENTORY_HOST=http://iop-core-host-inventory-api:8081',
        ],
        'Secret'        => [
          "${database_username_secret_name},type=env,target=DB_USERNAME",
          "${database_password_secret_name},type=env,target=DB_PASSWORD",
          "${database_name_secret_name},type=env,target=DB_DATABASE",
          "${database_host_secret_name},type=env,target=DB_HOST",
          "${database_port_secret_name},type=env,target=DB_PORT",
        ],
      },
      'Service'   => {
        'Environment' => 'REGISTRY_AUTH_FILE=/etc/foreman/registry-auth.json',
        'Restart'     => 'on-failure',
      },
      'Install'   => { 'WantedBy' => 'default.target' },
    },
  }
}