Puppet Class: iop::service_vmaas

Defined in:
manifests/service_vmaas.pp

Overview

Class: iop::service_vmaas

Install and configure the VMAAS reposcan service

Parameters:

$image

The container image

$ensure

Ensure service is present or absent

$database_user

Username for the vmaas database

$database_name

Name of the vmaas database

$database_password

Password for the vmaas database

$database_host

Host for the vmaas database

$database_port

Port for the vmaas database

Parameters:

  • image (String[1]) (defaults to: 'quay.io/iop/vmaas:latest')
  • ensure (Enum['present', 'absent']) (defaults to: 'present')
  • database_user (String[1]) (defaults to: 'vmaas_admin')
  • database_name (String[1]) (defaults to: 'vmaas_db')
  • database_password (String[1]) (defaults to: extlib::cache_data('iop_cache_data', 'vmaas_db_password', extlib::random_password(32)))
  • database_host (String[1]) (defaults to: '/var/run/postgresql')
  • database_port (Stdlib::Port) (defaults to: 5432) 


21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
 
# File 'manifests/service_vmaas.pp', line 21

class iop::service_vmaas (
  String[1] $image = 'quay.io/iop/vmaas:latest',
  Enum['present', 'absent'] $ensure = 'present',
  String[1] $database_user = 'vmaas_admin',
  String[1] $database_name = 'vmaas_db',
  String[1] $database_password = extlib::cache_data('iop_cache_data', 'vmaas_db_password', extlib::random_password(32)),
  String[1] $database_host = '/var/run/postgresql',
  Stdlib::Port $database_port = 5432,
) {
  include podman
  include iop::core_network
  include iop::core_kafka
  include iop::core_gateway
  include iop::database
  include iop::cvemap_downloader
  include certs::iop

  $service_name = 'iop-service-vmaas-reposcan'
  $server_ca_cert_secret_name = "${service_name}-server-ca-cert"
  $database_username_secret_name = "${service_name}-database-username"
  $database_password_secret_name = "${service_name}-database-password"
  $database_name_secret_name = "${service_name}-database-name"
  $database_host_secret_name = "${service_name}-database-host"
  $database_port_secret_name = "${service_name}-database-port"

  $socket_volume = $database_host ? {
    /^\/var\/run\/postgresql/ => ['/var/run/postgresql:/var/run/postgresql:rw'],
    default                   => [],
  }

  podman::secret { $server_ca_cert_secret_name:
    ensure => $ensure,
    path   => $certs::iop::server_ca_cert,
  }

  podman::secret { $database_username_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_user),
  }

  podman::secret { $database_password_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_password),
  }

  podman::secret { $database_name_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_name),
  }

  podman::secret { $database_host_secret_name:
    ensure => $ensure,
    secret => Sensitive($database_host),
  }

  podman::secret { $database_port_secret_name:
    ensure => $ensure,
    secret => Sensitive(String($database_port)),
  }

  # Prevents errors if run from /root etc.
  Postgresql_psql {
    cwd => '/',
  }

  include postgresql::client, postgresql::server

  postgresql::server::db { $database_name:
    user     => $database_user,
    password => postgresql::postgresql_password($database_user, $database_password),
    owner    => $database_user,
    encoding => 'utf8',
    locale   => 'en_US.utf8',
  }

  podman::volume { 'iop-service-vmaas-data':
    ensure => $ensure,
  }

  podman::quadlet { 'iop-service-vmaas-reposcan':
    ensure       => $ensure,
    quadlet_type => 'container',
    user         => 'root',
    defaults     => {},
    require      => [
      Podman::Network['iop-core-network'],
      Podman::Volume['iop-service-vmaas-data'],
      Postgresql::Server::Db[$database_name],
      Podman::Secret[$server_ca_cert_secret_name],
      Podman::Secret[$database_username_secret_name],
      Podman::Secret[$database_password_secret_name],
      Podman::Secret[$database_name_secret_name],
      Podman::Secret[$database_host_secret_name],
      Podman::Secret[$database_port_secret_name],
    ],
    settings     => {
      'Unit'      => {
        'Description' => 'VMAAS Reposcan Service',
      },
      'Container' => {
        'Image'         => $image,
        'ContainerName' => 'iop-service-vmaas-reposcan',
        'Network'       => 'iop-core-network',
        'Exec'          => '/vmaas/entrypoint.sh database-upgrade reposcan',
        'Environment'   => [
          'PROMETHEUS_PORT=8085',
          'PROMETHEUS_MULTIPROC_DIR=/tmp/prometheus_multiproc_dir',
          'SYNC_REPO_LIST_SOURCE=katello',
          'SYNC_REPOS=yes',
          'SYNC_CVE_MAP=yes',
          'SYNC_CPE=no',
          'SYNC_CSAF=no',
          'SYNC_RELEASES=no',
          'SYNC_RELEASE_GRAPH=no',
          'KATELLO_URL=http://iop-core-gateway:9090',
          'REDHAT_CVEMAP_URL=http://iop-core-gateway:9090/pub/iop/data/meta/v1/cvemap.xml',
        ],
        'Volume'        => $socket_volume + [
          'iop-service-vmaas-data:/data',
        ],
        'Secret'        => [
          "${server_ca_cert_secret_name},target=/katello-server-ca.crt,mode=0440,type=mount",
          "${database_username_secret_name},type=env,target=POSTGRESQL_USER",
          "${database_password_secret_name},type=env,target=POSTGRESQL_PASSWORD",
          "${database_name_secret_name},type=env,target=POSTGRESQL_DATABASE",
          "${database_host_secret_name},type=env,target=POSTGRESQL_HOST",
          "${database_port_secret_name},type=env,target=POSTGRESQL_PORT",
        ],
      },
      'Service'   => {
        'Environment' => 'REGISTRY_AUTH_FILE=/etc/foreman/registry-auth.json',
        'Restart'     => 'on-failure',
      },
      'Install'   => {
        'WantedBy' => ['multi-user.target', 'default.target'],
      },
    },
  }

  podman::quadlet { 'iop-service-vmaas-webapp-go':
    ensure       => $ensure,
    quadlet_type => 'container',
    user         => 'root',
    defaults     => {},
    require      => [
      Podman::Network['iop-core-network'],
      Postgresql::Server::Db[$database_name],
      Podman::Secret[$database_username_secret_name],
      Podman::Secret[$database_password_secret_name],
      Podman::Secret[$database_name_secret_name],
      Podman::Secret[$database_host_secret_name],
      Podman::Secret[$database_port_secret_name],
    ],
    settings     => {
      'Unit'      => {
        'Description' => 'VMAAS Webapp-Go Service',
        'Wants'       => ['iop-service-vmaas-reposcan.service'],
        'After'       => ['iop-service-vmaas-reposcan.service'],
      },
      'Container' => {
        'Image'         => $image,
        'ContainerName' => 'iop-service-vmaas-webapp-go',
        'Network'       => 'iop-core-network',
        'Exec'          => '/vmaas/entrypoint.sh webapp-go',
        'Environment'   => [
          'REPOSCAN_PUBLIC_URL=http://iop-service-vmaas-reposcan:8000',
          'REPOSCAN_PRIVATE_URL=http://iop-service-vmaas-reposcan:10000',
          'CSAF_UNFIXED_EVAL_ENABLED=FALSE',
          'GIN_MODE=release',
        ],
        'Secret'        => [
          "${database_username_secret_name},type=env,target=POSTGRESQL_USER",
          "${database_password_secret_name},type=env,target=POSTGRESQL_PASSWORD",
          "${database_name_secret_name},type=env,target=POSTGRESQL_DATABASE",
          "${database_host_secret_name},type=env,target=POSTGRESQL_HOST",
          "${database_port_secret_name},type=env,target=POSTGRESQL_PORT",
        ],
        'Volume'        => $socket_volume,
      },
      'Service'   => {
        'Environment' => 'REGISTRY_AUTH_FILE=/etc/foreman/registry-auth.json',
        'Restart'     => 'on-failure',
      },
      'Install'   => {
        'WantedBy' => ['multi-user.target', 'default.target'],
      },
    },
  }
}