Puppet Class: puppet::agent::config

Inherits:
puppet::config
Defined in:
manifests/agent/config.pp

Overview

Puppet agent configuration



3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
 
# File 'manifests/agent/config.pp', line 3

class puppet::agent::config inherits puppet::config {
  puppet::config::agent{
    'classfile':         value => $puppet::classfile;
    'localconfig':       value => '$vardir/localconfig';
    'default_schedules': value => false;
    'report':            value => $puppet::report;
    'masterport':        value => $puppet::port;
    'environment':       value => $puppet::environment;
    'splay':             value => $puppet::splay;
    'splaylimit':        value => $puppet::splaylimit;
    'runinterval':       value => $puppet::runinterval;
    'noop':              value => $puppet::agent_noop;
    'usecacheonfailure': value => $puppet::usecacheonfailure;
  }
  if $puppet::http_connect_timeout != undef {
    puppet::config::agent {
      'http_connect_timeout': value => $puppet::http_connect_timeout;
    }
  }
  if $puppet::http_read_timeout != undef {
    puppet::config::agent {
      'http_read_timeout': value => $puppet::http_read_timeout;
    }
  }
  if $puppet::prerun_command {
    puppet::config::agent {
      'prerun_command':  value => $puppet::prerun_command;
    }
  }
  if $puppet::postrun_command {
    puppet::config::agent {
      'postrun_command': value => $puppet::postrun_command;
    }
  }

  unless $puppet::pluginsync {
    if versioncmp($facts['puppetserver'], '6.0.0') >= 0 {
      fail('pluginsync is no longer a setting in Puppet 6')
    } else {
      puppet::config::agent { 'pluginsync':
        value => $puppet::pluginsync,
      }
    }
  }

  $puppet::agent_additional_settings.each |$key,$value| {
    puppet::config::agent { $key: value => $value }
  }

  if $puppet::runmode == 'service' {
    $should_start = 'yes'
  } else {
    $should_start = 'no'
  }

  if $facts['os']['family'] == 'Debian' {
    augeas {'puppet::set_start':
      context => '/files/etc/default/puppet',
      changes => "set START ${should_start}",
      incl    => '/etc/default/puppet',
      lens    => 'Shellvars.lns',
    }
    if $puppet::remove_lock {
      file {'/var/lib/puppet/state/agent_disabled.lock':
        ensure => absent,
      }
    }
  }
}