54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
|
# File 'manifests/init.pp', line 54
define systemd_cron (
Optional[String] $command = undef,
Optional[String] $service_description = undef,
Optional[String] $on_calendar = undef,
Optional[Variant[Integer,String]] $on_boot_sec = undef,
Optional[Variant[Integer,String]] $on_unitactive_sec = undef,
String $timer_description = "timer for ${service_description}",
Variant[Boolean,Enum['present','absent']] $ensure = true,
String $type = 'oneshot',
String $user = 'root',
Optional[Array] $additional_timer_params = undef, # remove in V3
Optional[Array] $additional_service_params = undef, # remove in V3
Systemd::Unit::Service $service_overrides = {},
Systemd::Unit::Timer $timer_overrides = {},
Systemd::Unit::Unit $timer_unit_overrides = {},
Systemd::Unit::Unit $service_unit_overrides = {},
) {
if $ensure == true or $ensure == 'present' {
if ! $on_calendar and ! $on_boot_sec {
fail("systemd_cron['${title}']: you need to define on_calendar or on_boot_sec")
}
if ! $command {
fail("systemd_cron['${title}']: you need to define command")
}
}
# remove in V3
if $additional_timer_params and ( $timer_overrides != {} or $timer_unit_overrides != {}) {
fail("systemd_cron['${title}']: you can't use additional_timer_params and timer_overrides at the same time")
}
# remove in V3
if $additional_service_params and ( $service_overrides != {} or $service_unit_overrides != {}) {
fail("systemd_cron['${title}']: you can't use additional_service_params and service_overrides at the same time")
}
# remove in V3
if $additional_timer_params {
warning("Parameter 'additional_timer_params is deprecated. Please use the alternative parameter 'timer_overrides' instead.")
$_timer_overrides = $additional_timer_params.reduce({}) |Hash $memo, $item| {
$matches = $item.match(/^(.+)=(.*)$/)
notice( "matches: ${matches}")
$memo + { $matches[1] => $matches[2] }
}
} else {
$_timer_overrides = $timer_overrides
}
# remove in V3
if $additional_service_params {
warning("Parameter 'additional_service_params is deprecated. Please use the alternative parameter 'service_overrides' instead.")
$_service_overrides = $additional_service_params.reduce({}) |Hash $memo, $item| {
$matches = $item.match(/^(.+)=(.*)$/)
notice( "matches: ${matches}")
$memo + { $matches[1] => $matches[2] }
}
} else {
$_service_overrides = $service_overrides
}
$file_ensure = $ensure ? {
false => 'absent',
'absent' => 'absent',
default => 'present'
}
$service_ensure = $ensure ? {
false => false,
'absent' => false,
default => true,
}
$unit_name = regsubst($title, '/' , '_', 'G')
systemd::manage_unit { "${unit_name}_cron.service":
ensure => $file_ensure,
unit_entry => delete_undef_values({
'Description' => $service_description ,
}) + $service_unit_overrides,
service_entry => {
'ExecStart' => $command,
'User' => $user,
'Type' => $type,
} + $_service_overrides,
}
systemd::manage_unit { "${unit_name}_cron.timer":
ensure => $file_ensure,
unit_entry => delete_undef_values({
'Description' => $timer_description ,
}) + $timer_unit_overrides,
timer_entry => delete_undef_values({
'OnCalendar' => $on_calendar,
'OnBootSec' => $on_boot_sec,
'OnUnitActiveSec' => $on_unitactive_sec,
}) + $_timer_overrides,
}
service { "${unit_name}_cron.timer":
ensure => $service_ensure,
enable => $service_ensure,
}
if $service_ensure {
Systemd::Unit_file["${unit_name}_cron.service"] -> Systemd::Unit_file["${unit_name}_cron.timer"] -> Service["${unit_name}_cron.timer"]
} else {
Service["${unit_name}_cron.timer"] -> Systemd::Unit_file["${unit_name}_cron.timer"] -> Systemd::Unit_file["${unit_name}_cron.service"]
}
}
|