Puppet Class: php::fpm::daemon

Inherits:
::php::params
Defined in:
manifests/fpm/daemon.pp

Overview

Class: php::fpm::daemon

Install the PHP FPM daemon. See php::fpm::conf for configuring its pools.

Sample Usage:

include php::fpm::daemon

Parameters:

  • ensure (Any) (defaults to: 'present')
  • package_name (Any) (defaults to: $::php::params::fpm_package_name)
  • service_name (Any) (defaults to: $::php::params::fpm_service_name)
  • service_restart (Any) (defaults to: $::php::params::fpm_service_restart)
  • fpm_pool_dir (Any) (defaults to: $::php::params::fpm_pool_dir)
  • fpm_conf_dir (Any) (defaults to: $::php::params::fpm_conf_dir)
  • error_log (Any) (defaults to: $::php::params::fpm_error_log)
  • pid (Any) (defaults to: $::php::params::fpm_pid)
  • syslog_facility (Any) (defaults to: 'daemon')
  • syslog_ident (Any) (defaults to: 'php-fpm')
  • log_level (Any) (defaults to: 'notice')
  • emergency_restart_threshold (Any) (defaults to: '0')
  • emergency_restart_interval (Any) (defaults to: '0')
  • process_control_timeout (Any) (defaults to: '0')
  • process_max (Any) (defaults to: undef)
  • process_priority (Any) (defaults to: undef)
  • rlimit_files (Any) (defaults to: undef)
  • rlimit_core (Any) (defaults to: undef)
  • log_owner (Any) (defaults to: undef)
  • log_group (Any) (defaults to: undef)
  • log_dir_mode (Any) (defaults to: '0770') 


8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
 
# File 'manifests/fpm/daemon.pp', line 8

class php::fpm::daemon (
  $ensure                      = 'present',
  $package_name                = $::php::params::fpm_package_name,
  $service_name                = $::php::params::fpm_service_name,
  $service_restart             = $::php::params::fpm_service_restart,
  $fpm_pool_dir                = $::php::params::fpm_pool_dir,
  $fpm_conf_dir                = $::php::params::fpm_conf_dir,
  $error_log                   = $::php::params::fpm_error_log,
  $pid                         = $::php::params::fpm_pid,
  $syslog_facility             = 'daemon',
  $syslog_ident                = 'php-fpm',
  $log_level                   = 'notice',
  $emergency_restart_threshold = '0',
  $emergency_restart_interval  = '0',
  $process_control_timeout     = '0',
  $process_max                 = undef,
  $process_priority            = undef,
  $rlimit_files                = undef,
  $rlimit_core                 = undef,
  $log_owner                   = undef,
  $log_group                   = undef,
  $log_dir_mode                = '0770',
) inherits ::php::params {

  # Hack-ish to default to user for group too
  $log_group_final = $log_group ? {
    false   => $log_owner,
    default => $log_group,
  }

  package { $package_name: ensure => $ensure }

  if ( $ensure != 'absent' ) {

    service { $service_name:
      ensure    => 'running',
      enable    => true,
      restart   => "service ${service_name} ${service_restart}",
      hasstatus => true,
      require   => Package[$package_name],
    }

    # When running FastCGI, we don't always use the same user
    file { '/var/log/php-fpm':
      ensure  => 'directory',
      owner   => $log_owner,
      group   => $log_group_final,
      mode    => $log_dir_mode,
      require => Package[$package_name],
    }

    file { "${fpm_conf_dir}/php-fpm.conf":
      owner   => 'root',
      group   => 'root',
      mode    => '0644',
      content => template('php/fpm/php-fpm.conf.erb'),
      require => Package[$package_name],
      notify  => Service[$service_name],
    }

  }

}