Puppet Class: cis_security_hardening::rules::aide_installed

Defined in:
manifests/rules/aide_installed.pp

Summary

Ensure AIDE is installed

Overview

AIDE takes a snapshot of filesystem state including modification times, permissions, and file hashes which can then be used to compare against the current state of the filesystem to detect modifications to the system.

Rationale: By monitoring the filesystem state compromised files can be detected to prevent or limit the exposure of accidental or malicious misconfigurations or modified binaries.

Examples:

class { 'cis_security_hardening::rules::aide_installed':
    enforce => true,
}

Parameters:

  • enforce (Boolean) (defaults to: false) —

    Enforce the rule

  • aide_init_timeout (Integer) (defaults to: 1800) —

    Timeout in secords for aide init command to complete



24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
 
# File 'manifests/rules/aide_installed.pp', line 24

class cis_security_hardening::rules::aide_installed (
  Boolean $enforce = false,
  Integer $aide_init_timeout = 1800,
) {
  if $enforce {
    case $facts['os']['name'].downcase() {
      'ubuntu', 'debian': {
        ensure_packages(['aide', 'aide-common'], {
            ensure => installed,
            notify => Exec['aidedb-ubuntu-init'],
        })

        exec { 'aidedb-ubuntu-init':
          command     => 'aideinit',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          refreshonly => true,
          logoutput   => true,
          notify      => Exec['rename_aidedb_ubuntu'],
          require     => Package['aide', 'aide-common'],
          timeout     => $aide_init_timeout,
        }

        exec { 'rename_aidedb_ubuntu':
          command     => 'mv /var/lib/aide/aide.db.new /var/lib/aide/aide.db',
          creates     => '/var/lib/aide/aide.db',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          logoutput   => true,
          refreshonly => true,
          require     => Package['aide', 'aide-common'],
        }
      }
      'centos', 'redhat', 'almalinux', 'rocky': {
        ensure_packages(['aide'], {
            ensure => installed,
            notify => Exec['aidedb'],
        })

        exec { 'aidedb':
          command     => 'aide --init',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          refreshonly => true,
          notify      => Exec['rename_aidedb'],
          require     => Package['aide'],
        }

        exec { 'rename_aidedb':
          command     => 'mv /var/lib/aide/aide.db.new.gz /var/lib/aide/aide.db.gz',
          creates     => '/var/lib/aide/aide.db.gz',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          logoutput   => true,
          refreshonly => true,
          require     => Package['aide'],
        }
      }
      'sles': {
        ensure_packages(['aide'], {
            ensure => installed,
            notify => Exec['aidedb'],
        })

        exec { 'aidedb':
          command     => 'aide --init',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          refreshonly => true,
          notify      => Exec['rename_aidedb'],
          require     => Package['aide'],
        }

        exec { 'rename_aidedb':
          command     => 'mv /var/lib/aide/aide.db.new /var/lib/aide/aide.db',
          creates     => '/var/lib/aide/aide.db',
          path        => ['/sbin', '/usr/sbin', '/bin', '/usr/bin'],
          logoutput   => true,
          refreshonly => true,
          require     => Package['aide'],
        }
      }
      default: {
      }
    }
  }
}