Puppet Class: cis_security_hardening::rules::avahi

Defined in:
manifests/rules/avahi.pp

Summary

Ensure Avahi Server is not enabled

Overview

Avahi is a free zeroconf implementation, including a system for multicast DNS/DNS-SD service discovery. Avahi allows programs to publish and discover services and hosts running on a local network with no specific configuration. For example, a user can plug a computer into a network and Avahi automatically finds printers to print to, files to look at and people to talk to, as well as network services running on the machine.

Rationale: Automatic discovery of network services is not normally required for system functionality. It is recommended to disable the service to reduce the potential attack surface.

Examples:

class { 'cis_security_hardening::rules::avahi':
    enforce => true,
}

Parameters:

  • enforce (Boolean) (defaults to: false) —

    Enforce the rule



22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
 
# File 'manifests/rules/avahi.pp', line 22

class cis_security_hardening::rules::avahi (
  Boolean $enforce = false,
) {
  if $enforce {
    $ensure = $facts['os']['family'].downcase() ? {
      'suse'  => 'absent',
      default => 'purged'
    }

    case $facts['os']['name'].downcase {
      'redhat', 'centos': {
        if $facts['os']['release']['major'] >= '8' {
          ensure_resource('service', ['avahi-daemon.socket'], {
              ensure => 'stopped',
              enable => false,
          })
          ensure_resource('service', ['avahi-daemon.service'], {
              ensure => 'stopped',
              enable => false,
          })
        } else {
          ensure_resource('service', ['avahi-daemon'], {
              ensure => 'stopped',
              enable => false,
          })
        }
      }
      'almalinux', 'rocky': {
        ensure_resource('service', ['avahi-daemon.socket'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_resource('service', ['avahi-daemon.service'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_packages(['avahi-autoipd', 'avahi'], {
            ensure => $ensure,
        })
      }
      'ubuntu': {
        ensure_resource('service', ['avahi-daemon.socket'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_resource('service', ['avahi-daemon.service'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_packages(['avahi-daemon'], {
            ensure => $ensure,
        })
      }
      'debian': {
        if $facts['os']['release']['major'] > '10' {
          exec { 'stop avahi service':
            command => 'systemctl stop avahi-demon.service',
            path    => ['/bin', '/usr/bin'],
            returns => [0, 5],
            unless  => "test \"$(systemctl is-active avahi-daemon.service)\" = \"inactive\"",
            require => Exec['stop avahi socket'],
          }

          exec { 'stop avahi socket':
            command => 'systemctl stop avahi-demon.socket',
            path    => ['/bin', '/usr/bin'],
            returns => [0, 5],
            unless  => "test \"$(systemctl is-active avahi-daemon.socket)\" = \"inactive\"",
          }

          ensure_packages(['avahi-daemon'], {
              ensure => $ensure,
              require => [Exec['stop avahi service'], Exec['stop avahi socket']]
          })
        } else {
          ensure_resource('service', ['avahi-daemon'], {
              ensure => 'stopped',
              enable => false,
          })
        }
      }
      'sles': {
        ensure_resource('service', ['avahi-daemon.socket'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_resource('service', ['avahi-daemon.service'], {
            ensure => 'stopped',
            enable => false,
        })
        ensure_packages(['avahi-autoipd', 'avahi'], {
            ensure => $ensure,
        })
      }
      default: {
        # Nothing to be done yet
      }
    }
  }
}