Puppet Class: cis_security_hardening::rules::fat

Defined in:
manifests/rules/fat.pp

Summary

Ensure mounting of FAT filesystems is disabled

Overview

The FAT filesystem format is primarily used on older windows systems and portable USB drives or flash modules. It comes in three types FAT12 , FAT16 , and FAT32 all of which are supported by the vfat kernel module.

Rationale: Removing support for unneeded filesystem types reduces the local attack surface of the system. If this filesystem type is not needed, disable it.

Examples:

class { 'cis_security_hardening::rules::fat':
    enforce => true,
}

Parameters:

  • enforce (Boolean) (defaults to: false) —

    Enforce the rule



21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
# File 'manifests/rules/fat.pp', line 21

class cis_security_hardening::rules::fat (
  Boolean $enforce = false,
) {
  if $enforce {
    case $facts['os']['name'].downcase() {
      'ubuntu', 'debian': {
        kmod::install { 'vfat':
          command => '/bin/true',
        }
      }
      'centos', 'almalinux', 'rocky', 'redhat': {
        case $facts['os']['release']['major'] {
          '7': {
            kmod::install { 'fat':
              command => '/bin/true',
            }
            kmod::install { 'vfat':
              command => '/bin/true',
            }
            kmod::install { 'msdos':
              command => '/bin/true',
            }
          }
          '8': {
            kmod::install { 'vfat':
              command => '/bin/true',
            }
          }
          default: {}
        }
      }
      'sles': {
        kmod::install { 'fat':
          command => '/bin/true',
        }
        kmod::install { 'vfat':
          command => '/bin/true',
        }
        kmod::install { 'msdos':
          command => '/bin/true',
        }
      }
      default: {}
    }
  }
}