Puppet Class: cis_security_hardening::rules::fips_bootloader

Defined in:
manifests/rules/fips_bootloader.pp

Summary

Ensure FIPS mode is enabled

Overview

The operating system must implement NIST FIPS-validated cryptography to protect classified information and for the following: to provision digital signatures, to generate cryptographic hashes, and to protect unclassified information requiring confidentiality and cryptographic protection in accordance with applicable federal laws, Executive Orders, directives, policies, regulations, and standards.

Rationale: Use of weak or untested encryption algorithms undermines the purposes of utilizing encryption to protect data. The operating system must implement cryptographic modules adhering to the higher standards approved by the federal government since this provides assurance they have been tested and validated. Satisfies: SRG-OS-000396-GPOS-00176, SRG-OS-000478-GPOS-00223

Impact: Enabling a FIPS mode on a pre-existing system involves a number of modifications to the Ubuntu operating system. Refer to the Ubuntu Server 18.04 FIPS 140-2 security policy document for instructions. Note: A subscription to the “Ubuntu Advantage” plan is required in order to obtain the FIPS Kernel cryptographic modules and enable FIPS.

Examples:

class { 'cis_security_hardening::rules::fips_bootloader':
  enforce => true,
}

Parameters:

  • enforce (Boolean) (defaults to: false) —

    Enforce the rule.



30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
 
# File 'manifests/rules/fips_bootloader.pp', line 30

class cis_security_hardening::rules::fips_bootloader (
  Boolean $enforce = false,
) {
  if $enforce {
    kernel_parameter { 'fips':
      value  => '1',
      notify => Exec['fips-grub-config'],
    }

    $boot_uuid = fact('cis_security_hardening.grub.boot_part_uuid')
    if $boot_uuid != undef and $facts['os']['name'].downcase() == 'redhat' {
      kernel_parameter { 'boot':
        value  => $boot_uuid,
        notify => Exec['fips-grub-config'],
      }
    }

    case $facts['os']['family'].downcase() {
      'debian': {
        $cmd = 'update-grub'
      }
      'suse', 'redhat': {
        $cmd = 'grub2-mkconfig -o /boot/grub2/grub.cfg'
      }
      default: {
        $cmd = ''
      }
    }

    if ! empty($cmd) {
      exec { 'fips-grub-config':
        command     => $cmd,
        path        => ['/bin', '/usr/bin', '/sbin', '/usr/sbin'],
        refreshonly => true,
      }
    }
  }
}