Puppet Class: burp::server

Defined in:
manifests/server.pp

Overview

Class burp::server

This class configures the BURP backup server.

Parameters

ca_config_file

Default: /etc/burp/CA.cnf CA configuration file.

ca_dir

Default: /var/lib/burp/CA Directory where all CA related files are saved to.

ca_enabled

Default: true Whether to enable the BURP CA or not.

clientconfig_dir

Default: /etc/burp/clients Directory to save client configuration to.

clientconfig_tag

Default: $::fqdn Puppet tag to collect exported ‘burp::clientconfig` resources.

clientconfigs

Default: {} Hash of ‘::burp::clientconfig` instances. Will be passed to `create_resources`.

config_file

Default: /etc/burp/burp-server.conf Configuration file to put BURP backup server configuration into.

configuration

Default: {} Hash of server configuration directives. See man page of BURP, section “SERVER CONFIGURATION FILE OPTIONS”, for a detailed list of all possible values. A big bunch of default values are already prepared (see code below). Values defined in this hash will get merged and will override the default parameters!

group

Default: burp Group to run BURP backup server under.

user

Default: burp User to run BURP backup server under.

config_file_mode

Default: 0600 Mode of burp config dirs and files

homedir_file_mode

Default: 0750 Mode of burp data dirs and files

manage_clientconfig

Default: true Collect ‘::burp::clientconfig` exported resources, filtered by `clientconfig_tag`.

manage_rsyslog

Default: true Put a rsyslog config file under /etc/rsyslog.d/21-burp.conf to filter syslog messages from BURP backup server and put them into /var/log/burp/burp.log.

manage_service

Default: true Manage the BURP backup system service.

manage_user

Default: true Manage the BURP backup system service user.

service_enable

Default: true Enable the BURP backup system service on system boot.

service_ensure

Default: running Desired state of the BURP backup system service.

service_name

Default: burp Name of the BURP backup system service.

ssl_cert

Default: /var/lib/burp/ssl_cert-server.pem BURP backup server SSL certificate file.

ssl_cert_ca

Default: /var/lib/burp/ssl_cert_ca.pem BURP backup server SSL CA certificate file.

ssl_dhfile

Default: /var/lib/burp/dhfile.pem BURP backup server SSL DH params file.

ssl_key

Default: /var/lib/burp/ssl_cert-server.key BURP backup server SSL certificate key file.

user_home

Default: /var/lib/burp BURP backup server home and working directory.

config_file_replace

Default: true Boolean stating whether to overwrite local changes to config files.

scripts_replace

Default: true Boolean stating whether to overwrite local changes to scripts.

Authors

Tobias Brunner <tobias.brunner@vshn.ch>

Copyright 2015 Tobias Brunner, VSHN AG

Parameters:

  • ca_config_file (Any) (defaults to: '/etc/burp/CA.cnf')
  • ca_dir (Any) (defaults to: '/var/lib/burp/CA')
  • ca_enabled (Any) (defaults to: true)
  • clientconfig_dir (Any) (defaults to: '/etc/burp/clients')
  • clientconfig_tag (Any) (defaults to: $::fqdn)
  • clientconfigs (Any) (defaults to: {})
  • config_file (Any) (defaults to: '/etc/burp/burp-server.conf')
  • configuration (Any) (defaults to: {})
  • user (Any) (defaults to: 'burp')
  • group (Any) (defaults to: 'burp')
  • config_file_mode (Any) (defaults to: '0600')
  • homedir_file_mode (Any) (defaults to: '0750')
  • manage_clientconfig (Any) (defaults to: true)
  • manage_rsyslog (Any) (defaults to: true)
  • manage_service (Any) (defaults to: true)
  • manage_user (Any) (defaults to: true)
  • service_enable (Any) (defaults to: true)
  • service_ensure (Any) (defaults to: 'running')
  • service_name (Any) (defaults to: 'burp')
  • ssl_cert (Any) (defaults to: '/var/lib/burp/ssl_cert-server.pem')
  • ssl_cert_ca (Any) (defaults to: '/var/lib/burp/ssl_cert_ca.pem')
  • ssl_dhfile (Any) (defaults to: '/var/lib/burp/dhfile.pem')
  • ssl_key (Any) (defaults to: '/var/lib/burp/ssl_cert-server.key')
  • user_home (Any) (defaults to: '/var/lib/burp')
  • config_file_replace (Any) (defaults to: true)
  • scripts_replace (Any) (defaults to: true) 


124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
 
# File 'manifests/server.pp', line 124

class burp::server (
  $ca_config_file = '/etc/burp/CA.cnf',
  $ca_dir = '/var/lib/burp/CA',
  $ca_enabled = true,
  $clientconfig_dir = '/etc/burp/clients',
  $clientconfig_tag = $::fqdn,
  $clientconfigs = {},
  $config_file = '/etc/burp/burp-server.conf',
  $configuration = {},
  $user = 'burp',
  $group = 'burp',
  $config_file_mode = '0600',
  $homedir_file_mode = '0750',
  $manage_clientconfig = true,
  $manage_rsyslog = true,
  $manage_service = true,
  $manage_user = true,
  $service_enable = true,
  $service_ensure = 'running',
  $service_name = 'burp',
  $ssl_cert = '/var/lib/burp/ssl_cert-server.pem',
  $ssl_cert_ca = '/var/lib/burp/ssl_cert_ca.pem',
  $ssl_dhfile = '/var/lib/burp/dhfile.pem',
  $ssl_key = '/var/lib/burp/ssl_cert-server.key',
  $user_home = '/var/lib/burp',
  $config_file_replace = true,
  $scripts_replace = true,
) {

  ## Input validation
  validate_absolute_path($ca_config_file)
  validate_absolute_path($ca_dir)
  validate_bool($ca_enabled)
  validate_absolute_path($clientconfig_dir)
  validate_string($clientconfig_tag)
  validate_absolute_path($config_file)
  validate_hash($configuration)
  validate_string($group)
  validate_bool($manage_clientconfig)
  validate_bool($manage_rsyslog)
  validate_bool($manage_service)
  validate_bool($manage_user)
  validate_bool($service_enable)
  validate_string($service_ensure)
  validate_string($service_name)
  validate_absolute_path($ssl_cert)
  validate_absolute_path($ssl_cert_ca)
  validate_absolute_path($ssl_dhfile)
  validate_absolute_path($ssl_key)
  validate_string($user)
  validate_absolute_path($user_home)
  validate_bool($config_file_replace)
  validate_bool($scripts_replace)

  include ::burp

  ## Default configuration parameters for BURP server
  # parameters coming from a default BURP installation (most of them)
  $_default_configuration = {
    'ca_burp_ca'                  => '/usr/sbin/burp_ca',
    'ca_conf'                     => $ca_config_file,
    'ca_name'                     => 'burpCA',
    'ca_server_name'              => $::fqdn,
    'client_can_delete'           => 1,
    'client_can_force_backup'     => 1,
    'client_can_list'             => 1,
    'client_can_restore'          => 1,
    'client_can_verify'           => 1,
    'clientconfdir'               => $clientconfig_dir,
    'directory'                   => $user_home,
    'group'                       => $group,
    'hardlinked_archive'          => 0,
    'keep'                        => [7, 4, 6],
    'max_children'                => 5,
    'max_status_children'         => 5,
    'mode'                        => 'server',
    'pidfile'                     => '/tmp/burp.server.pid',
    'port'                        => '4971',
    'ssl_cert'                    => $ssl_cert,
    'ssl_cert_ca'                 => $ssl_cert_ca,
    'ssl_dhfile'                  => $ssl_dhfile,
    'ssl_key'                     => $ssl_key,
    'status_port'                 => '4972',
    'stdout'                      => 0,
    'syslog'                      => 1,
    'timer_arg'                   => ['20h',
                                      'Mon,Tue,Wed,Thu,Fri,00,01,02,03,04,05,19,20,21,22,23',
                                      'Sat,Sun,00,01,02,03,04,05,06,07,08,17,18,19,20,21,22,23', ],
    'timer_script'                => '/usr/local/bin/burp_timer_script',
    'umask'                       => '0022',
    'user'                        => $user,
    'version_warn'                => 1,
    'working_dir_recovery_method' => 'delete',
  }
  $_configuration = merge($_default_configuration,$configuration)

  ## Prepare system user
  if $manage_user {
    user { $user:
      ensure     => present,
      comment    => 'BURP server service user',
      home       => $user_home,
      managehome => false,
      shell      => '/usr/sbin/nologin',
      system     => true,
    }
  }

  ## Write server configuration file
  file { $config_file:
    ensure  => file,
    content => template('burp/burp.conf.erb'),
    mode    => $config_file_mode,
    owner   => $user,
    group   => $group,
    require => Class['::burp::config'],
    replace => $config_file_replace,
  }

  ## Prepare CA
  if $ca_enabled {
    file { $ca_config_file:
      ensure  => file,
      content => template('burp/CA.cnf.erb'),
      mode    => $config_file_mode,
      owner   => $user,
      group   => $group,
      require => Class['::burp::config'],
      replace => $config_file_replace,
    }
  }

  ## Prepare working directories
  file { $user_home:
    ensure => directory,
    mode   => $homedir_file_mode,
    owner  => $user,
    group  => $group,
  } ->
  file { $clientconfig_dir:
    ensure  => directory,
    mode    => $config_file_mode,
    purge   => true,
    recurse => true,
    owner   => $user,
    group   => $group,
  }

  ## Deliver original scripts
  file { '/usr/local/bin/burp_timer_script':
    ensure  => file,
    mode    => '0755',
    source  => 'puppet:///modules/burp/timer_script',
    replace => $scripts_replace,
  }
  file { '/usr/local/bin/burp_summary_script':
    ensure  => file,
    mode    => '0755',
    source  => 'puppet:///modules/burp/summary_script',
    replace => $scripts_replace,
  }
  file { '/usr/local/bin/burp_notify_script':
    ensure  => file,
    mode    => '0755',
    source  => 'puppet:///modules/burp/notify_script',
    replace => $scripts_replace,
  }
  file { '/usr/local/bin/burp_ssl_extra_checks_script':
    ensure  => file,
    mode    => '0755',
    source  => 'puppet:///modules/burp/ssl_extra_checks_script',
    replace => $scripts_replace,
  }

  ## Instantiate clientconfigs
  if $manage_clientconfig {
    ::Burp::Clientconfig <<| tag == $clientconfig_tag |>>
    create_resources('::burp::clientconfig',$clientconfigs)
  }

  ## Manage service if enabled
  if $manage_service {
    File[$config_file] ~> Service['burp']
    if $manage_rsyslog {
      file { '/var/log/burp':
        ensure => directory,
        mode   => '0700',
        owner  => 'syslog',
        group  => 'adm',
      }
      # Pitfall: This file resource does not notify rsyslog and so it only comes active
      # after manually reloading rsyslog
      file { '/etc/rsyslog.d/21-burp.conf':
        ensure  => file,
        content => 'if $programname == \'burp\' then /var/log/burp/burp.log',
        before  => Service['burp'],
      }
    }
    augeas { '/etc/default/burp':
      context => '/files/etc/default/burp',
      changes => [
        'set RUN yes',
        "set DAEMON_ARGS '\"-c ${config_file}\"'",
      ],
    } ->
    service { 'burp':
      ensure => running,
      name   => $service_name,
      enable => true,
    }
  }

}