Puppet Class: pulp::install

Defined in:
manifests/install.pp

Overview

Class pulp::install

This class is called from pulp for install.



5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
# File 'manifests/install.pp', line 5

class pulp::install {

  package { ['pulp-server', 'pulp-selinux', 'python-pulp-streamer']:
    ensure => $::pulp::pulp_packages_ensure,
  }

  case $pulp::messaging_transport {
    /qpid/: {
      package { 'python-gofer-qpid':
        ensure => $pulp::gofer_package_ensure,
      }
    }
    /rabbitmq/: {
      package { 'python-gofer-amqp':
        ensure => $pulp::gofer_package_ensure,
      }
    }
    default: {
      fail("messaging transport: ${pulp::messaging_transport} not supported. Options are 'qpid' or 'rabbitmq'.")
    }
  }

  $pulp::enable_plugins.each |$plugin| {
    package { "pulp-${plugin}-plugins":
      ensure => $pulp::pulp_packages_ensure,
    }
  }

  if $pulp::manage_http_user {
    user { $pulp::http_user:
      ensure => present,
    }
  }

  if $pulp::manage_http_group {
    group { $pulp::http_group:
      ensure => present,
    }
  }

}