Puppet Class: wazuh::indexer

Defined in:
manifests/indexer.pp

Overview

Copyright © 2015, Wazuh Inc. Setup for Wazuh Indexer

Parameters:

  • indexer_network_host (Any) (defaults to: '0.0.0.0')
  • indexer_cluster_name (Any) (defaults to: 'wazuh-cluster')
  • indexer_node_name (Any) (defaults to: 'node-1')
  • indexer_node_max_local_storage_nodes (Any) (defaults to: '1')
  • indexer_service (Any) (defaults to: 'wazuh-indexer')
  • indexer_package (Any) (defaults to: 'wazuh-indexer')
  • indexer_version (Any) (defaults to: '4.14.4')
  • indexer_fileuser (Any) (defaults to: 'wazuh-indexer')
  • indexer_filegroup (Any) (defaults to: 'wazuh-indexer')
  • indexer_node_cert_source (Any) (defaults to: "puppet:///modules/archive/indexer-${indexer_node_name}.pem")
  • indexer_node_certkey_source (Any) (defaults to: "puppet:///modules/archive/indexer-${indexer_node_name}-key.pem")
  • indexer_node_rootca_source (Any) (defaults to: 'puppet:///modules/archive/root-ca.pem')
  • indexer_node_admincert_source (Any) (defaults to: 'puppet:///modules/archive/admin.pem')
  • indexer_node_adminkey_source (Any) (defaults to: 'puppet:///modules/archive/admin-key.pem')
  • indexer_path_data (Any) (defaults to: '/var/lib/wazuh-indexer')
  • indexer_path_logs (Any) (defaults to: '/var/log/wazuh-indexer')
  • indexer_path_certs (Any) (defaults to: '/etc/wazuh-indexer/certs')
  • indexer_security_init_lockfile (Any) (defaults to: '/var/tmp/indexer-security-init.lock')
  • full_indexer_reinstall (Any) (defaults to: false)
  • indexer_ip (Any) (defaults to: 'localhost')
  • indexer_port (Any) (defaults to: '9200')
  • indexer_discovery_hosts (Any) (defaults to: [])
  • indexer_cluster_initial_master_nodes (Any) (defaults to: ['node-1'])
  • indexer_cluster_cn (Any) (defaults to: ['node-1'])
  • jvm_options_memory (Any) (defaults to: '1g') 


3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
 
# File 'manifests/indexer.pp', line 3

class wazuh::indexer (
  # opensearch.yml configuration
  $indexer_network_host = '0.0.0.0',
  $indexer_cluster_name = 'wazuh-cluster',
  $indexer_node_name = 'node-1',
  $indexer_node_max_local_storage_nodes = '1',
  $indexer_service = 'wazuh-indexer',
  $indexer_package = 'wazuh-indexer',
  $indexer_version = '4.14.4',
  $indexer_fileuser = 'wazuh-indexer',
  $indexer_filegroup = 'wazuh-indexer',

  $indexer_node_cert_source = "puppet:///modules/archive/indexer-${indexer_node_name}.pem",
  $indexer_node_certkey_source = "puppet:///modules/archive/indexer-${indexer_node_name}-key.pem",
  $indexer_node_rootca_source = 'puppet:///modules/archive/root-ca.pem',
  $indexer_node_admincert_source = 'puppet:///modules/archive/admin.pem',
  $indexer_node_adminkey_source = 'puppet:///modules/archive/admin-key.pem',

  $indexer_path_data = '/var/lib/wazuh-indexer',
  $indexer_path_logs = '/var/log/wazuh-indexer',
  $indexer_path_certs = '/etc/wazuh-indexer/certs',
  $indexer_security_init_lockfile = '/var/tmp/indexer-security-init.lock',
  $full_indexer_reinstall = false, # Change to true when whant a full reinstall of Wazuh indexer

  $indexer_ip = 'localhost',
  $indexer_port = '9200',
  $indexer_discovery_hosts = [], # Empty array for single-node configuration
  $indexer_cluster_initial_master_nodes = ['node-1'],
  $indexer_cluster_cn = ['node-1'],

  # JVM options
  $jvm_options_memory = '1g',
) {
  # assign version according to the package manager
  case $facts['os']['family'] {
    'Debian': {
      $indexer_version_install = "${indexer_version}-*"
    }
    'Linux', 'RedHat', default: {
      $indexer_version_install = $indexer_version
    }
  }

  # install package
  package { 'wazuh-indexer':
    ensure => $indexer_version_install,
    name   => $indexer_package,
  }

  exec { "ensure full path of ${indexer_path_certs}":
    path    => '/usr/bin:/bin',
    command => "mkdir -p ${indexer_path_certs}",
    creates => $indexer_path_certs,
    require => Package['wazuh-indexer'],
  }
  -> file { $indexer_path_certs:
    ensure => directory,
    owner  => $indexer_fileuser,
    group  => $indexer_filegroup,
    mode   => '0500',
  }

  file { "${indexer_path_certs}/indexer-${indexer_node_name}.pem":
    ensure  => file,
    owner   => $indexer_fileuser,
    group   => $indexer_filegroup,
    mode    => '0400',
    source  => $indexer_node_cert_source,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file { "${indexer_path_certs}/indexer-${indexer_node_name}-key.pem":
    ensure  => file,
    owner   => $indexer_fileuser,
    group   => $indexer_filegroup,
    mode    => '0400',
    source  => $indexer_node_certkey_source,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file { "${indexer_path_certs}/root-ca.pem":
    ensure  => file,
    owner   => $indexer_fileuser,
    group   => $indexer_filegroup,
    mode    => '0400',
    source  => $indexer_node_rootca_source,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file { "${indexer_path_certs}/admin.pem":
    ensure  => file,
    owner   => $indexer_fileuser,
    group   => $indexer_filegroup,
    mode    => '0400',
    source  => $indexer_node_admincert_source,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file { "${indexer_path_certs}/admin-key.pem":
    ensure  => file,
    owner   => $indexer_fileuser,
    group   => $indexer_filegroup,
    mode    => '0400',
    source  => $indexer_node_adminkey_source,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file { 'configuration file':
    path    => '/etc/wazuh-indexer/opensearch.yml',
    content => template('wazuh/wazuh_indexer_yml.erb'),
    group   => $indexer_filegroup,
    mode    => '0660',
    owner   => $indexer_fileuser,
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file_line { 'Insert line initial size of total heap space':
    path    => '/etc/wazuh-indexer/jvm.options',
    line    => "-Xms${jvm_options_memory}",
    match   => '^-Xms',
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  file_line { 'Insert line maximum size of total heap space':
    path    => '/etc/wazuh-indexer/jvm.options',
    line    => "-Xmx${jvm_options_memory}",
    match   => '^-Xmx',
    require => Package['wazuh-indexer'],
    notify  => Service['wazuh-indexer'],
  }

  service { 'wazuh-indexer':
    ensure   => running,
    enable   => true,
    name     => $indexer_service,
    require  => Package['wazuh-indexer'],
    provider => 'systemd',
  }

  file_line { "Insert line limits nofile for ${indexer_fileuser}":
    path   => '/etc/security/limits.conf',
    line   => "${indexer_fileuser} - nofile  65535",
    match  => "^${indexer_fileuser} - nofile\s",
    notify => Service['wazuh-indexer'],
  }
  file_line { "Insert line limits memlock for ${indexer_fileuser}":
    path   => '/etc/security/limits.conf',
    line   => "${indexer_fileuser} - memlock unlimited",
    match  => "^${indexer_fileuser} - memlock\s",
    notify => Service['wazuh-indexer'],
  }

  if $full_indexer_reinstall {
    file { $indexer_security_init_lockfile:
      ensure  => absent,
      require => Package['wazuh-indexer'],
      before  => Exec['Initialize the Opensearch security index in Wazuh indexer'],
    }
  }
}